Question

我试图创建一个返回我从两个列表中定义的关联类型列表的函数。我考虑使用列表理解，但我不确定如何从每个列表中获取值。

type Assoc k v = [(k, v)]

makeAssoc :: [k] -> [v] -> [Assoc k v]
makeAssoc k v =
   [Assoc k' v' | k' <- k, ???]

main :: IO ()
main = do
    putStrLn $ show makeAssoc [1,2,3] [4,5,6]

如何实施makeAssoc k v？

Answer 1

您已将Assoc k v定义为别名（type不创建不同的类型，只为现有类型提供新名称 - 它们仍然可以互换）以获取(k, v)的列表。根据makeAssoc类型签名，它返回Assoc k v的列表。这意味着它实际上返回了(k, v)列表的列表，这可能不是您想要的。两种可能的解决方案：

解决方案1 - 将Assoc k v保留为元组列表，并从makeAssoc的类型签名中删除[]

type Assoc k v = [(k, v)]

makeAssoc :: [k] -> [v] -> Assoc k v

解决方案2 - 使Assoc k v成为元组的别名（不是元组列表）并将[]保存在makeAssoc的类型签名中

type Assoc k v = (k, v)

makeAssoc :: [k] -> [v] -> [Assoc k v]

另一个问题是type Assoc k v创建了可以在类型签名上使用的别名Assoc k v，但它不会创建具有相应数据构造函数的实际不同类型。所以你不能在函数的实际实现上使用Assoc k v。这意味着我们正在使用简单的元组，并且列表推导的正确语法将是（使用之前的第二个解决方案）：

type Assoc k v = (k, v)

makeAssoc :: [k] -> [v] -> [Assoc k v]
makeAssoc ks vs = [(k, v) | k <- ks, v <- vs]

但是列表推导会使用每个列表中的一个元素为您提供所有可能的对。例如：makeAssoc [1, 2] [3, 4]将导致[(1, 3), (1, 4), (2, 3), (2, 4)]。如果您确实需要一对一的直接映射，则应使用zip。

type Assoc k v = (k, v)

makeAssoc :: [k] -> [v] -> [Assoc k v]
makeAssoc ks vs = zip ks vs

通过此实现，结果将是[(1, 3), (2, 4)]。

编辑：

更进一步：当你在Haskell中获得更多经验时，你会发现你可以编写相同的东西：

type Assoc k v = (k, v)

makeAssoc :: [k] -> [v] -> [Assoc k v]
makeAssoc = zip

另一件事：如果你想要一个实际的不同类型，你可以使用data关键字和zipWith函数。

data Assoc k v = Assoc k v
    deriving (Show)

makeAssoc :: [k] -> [v] -> [Assoc k v]
makeAssoc ks vs = zipWith Assoc ks vs

或者省略以前的参数：

data Assoc k v = Assoc k v
    deriving (Show)

makeAssoc :: [k] -> [v] -> [Assoc k v]
makeAssoc = zipWith Assoc

Learn you a Haskell对于初学者来说是一个很好的资源，应该可以帮助您理解所有这些以及更多内容。

使用list comprehension在Haskell中创建一个新类型列表

1 个答案: