Question

我有以下批处理文件代码，可以使用HandBrakeCLI转换一些视频文件：

for /R .\test %%F in (*.mp4,*.avi,*.flv,*.mov,*.3gp,*.wmv,*.mkv,*.ts) do (
HandBrakeCLI -e x264 --x264-preset medium -q 35 --crop 0:0:0:0 --aencoder copy -i "%%~fF" -o "%%~dpF%%~nF_conv.mp4"
if exist "%%~dpF%%~nF_conv.mp4" (
    del "%%~fF"
    ren "%%~dpF%%~nF_conv.mp4" "%%~nxF"
    )
)

要在视频上应用此代码，我应该复制批处理文件和Handbrake.exe（及其相关文件夹）并将它们粘贴到名为test的文件夹旁边（在上面的代码中），然后更改名称“test”in批处理文件到该文件夹的名称，然后运行批处理文件。

你能否以我们在任意文件夹中运行它的方式编写批处理文件，因此它会提示输入包含视频的文件夹并编写路径（或者只是将文件夹拖放到命令行并按Enter键）没有移动文件和重命名“测试”？

Answer 1

您应该创建一个要从用户输入中读取的变量

set /p path=Videos path :

for /R %path% %%F in (*.mp4,*.avi,*.flv,*.mov,*.3gp,*.wmv,*.mkv,*.ts) do (
HandBrakeCLI -e x264 --x264-preset medium -q 35 --crop 0:0:0:0 --aencoder copy -i "%%~fF" -o "%%~dpF%%~nF_conv.mp4"
if exist "%%~dpF%%~nF_conv.mp4" (
    del "%%~fF"
    ren "%%~dpF%%~nF_conv.mp4" "%%~nxF"
    )
)

set /p可以正常工作，无论是写下路径还是使用文件夹拖放

Answer 2

使用"%~1"读取拖放参数。

for /R "%~1" %%F in (etc...)

如果在没有拖放（if "%~1"==""）的情况下启动批处理脚本，您可以使用folder chooser让用户浏览文件夹。

@if (@CodeSection == @Batch) @then

:: based on fchooser2.bat
:: https://stackoverflow.com/a/15906994/1683264

@echo off
setlocal

if "%~1"=="" (
    call :chooser dir || goto usage
) else if exist "%~1" (
    set "dir=%~1"
) else goto usage

for /R "%dir%" %%F in (*.mp4,*.avi,*.flv,*.mov,*.3gp,*.wmv,*.mkv,*.ts) do (
    HandBrakeCLI -e x264 --x264-preset medium -q 35 --crop 0:0:0:0 --aencoder copy -i "%%~fF" -o "%%~dpF%%~nF_conv.mp4"
    if exist "%%~dpF%%~nF_conv.mp4" (
        del "%%~fF"
        ren "%%~dpF%%~nF_conv.mp4" "%%~nxF"
    )
)

:: end main runtime.  Pause if dragged-and-dropped or double-clicked.
if /i "%cmdcmdline:~0,6%"=="cmd /c" pause
goto :EOF

:chooser <var_to_set>
setlocal
for /f "delims=" %%I in ('cscript /nologo /e:jscript "%~f0"') do (
    if not "%%~I"=="" if exist "%%~I" (
        endlocal & set "%~1=%%~I"
        exit /b 0
    )
)
exit /b 1

:usage
echo Usage: %~nx0 [directory]
goto :EOF

@end
// JScript portion

var shl = new ActiveXObject("Shell.Application");
var folder = shl.BrowseForFolder(0, "Please choose a folder.", 0, 0x00);
WSH.Echo(folder ? folder.self.path : '');

用于拖放路径的批处理文件分配给HandBraking视频

2 个答案: