Question

我是PL / SQL的新手。我在包中创建了一个流水线函数，它将参数输入作为数字数组（嵌套表）。

但是我在尝试通过SQL查询运行它时遇到了麻烦。请看下面的

我的输入数组

 CREATE OR REPLACE TYPE num_array is TABLE of number;

我的函数声明

CREATE OR REPLACE PACKAGE "my_pack" as
    TYPE myRecord is RECORD(column_a NUMBER);
    TYPE myTable IS TABLE of myRecord;

    FUNCTION My_Function(inp_param num_array) return myTable PIPELINED;

end my_pack;

我的功能定义

CREATE OR REPLACE PACKAGE BODY "my_pack" as

FUNCTION My_Function(inp_param num_array) return myTable PIPELINED as
        rec myRecord;
    BEGIN

        FOR i in 1..inp_param.count LOOP
            FOR e IN 
                (
                   SELECT column_a FROM  table_a where id=inp_param(i)

                )
                LOOP
                rec.column_a := e.column_a;

                PIPE ROW (rec); 

            END LOOP;
        END LOOP;

    RETURN;
END;

end my_pack;

这是我尝试从toad运行的最新代码。但它不起作用

declare
    myarray num_array;
    qrySQL varchar2(4000);
begin
    myarray := num_array(6341,6468);
    qrySQL := 'select * from TABLE(my_pack.My_Function(:myarray))';
    execute immediate qrySQL;
end;

所以我的问题是我如何从TOAD或SQL Developer向这个流水线函数提供数组。一个例子非常方便。

由于

Answer 1

错误相当清楚，你有一个你没有分配任何东西的绑定变量。您需要通过以下方式传递实际数组：

qrySQL := 'select * from TABLE(my_pack.My_Function(:myarray))';
execute immediate qrySQL using myarray;

如果你想从PL / SQL调用它，使用静态SQL作为游标，它可能更有用：

set serveroutput on
declare
    myarray num_array;
begin
    myarray := num_array(6341,6468);
    for r in (select * from TABLE(my_pack.My_Function(myarray))) loop
      dbms_output.put_line(r.column_a);
    end loop;
end;
/

或者只是静态地将其作为测试进行查询，对于固定值：

select * from TABLE(my_pack.My_Function(num_array(6341,6468)));

SQL Fiddle对函数进行了一些小调整，以消除我认为从编辑到发布的错误。

Oracle PL / SQL数组输入到流水线函数的参数

1 个答案: