Question

我正在从Fascicle 1重新实施Knuth的程序P：生成前500个素数。该程序生成前25个素数没有问题。该代码如下：

$ cat progp.S
/* print the first 500 primes */

#define n       %bx
#define j       %r12
#define k       %r13
#define pk      %r14d

        .data
fmt:    .asciz  "%d\n"
x:      .space 1000

        .text
        .globl  main
        .type   main, @function
main:
        pushq   %rbp
        movq    %rsp, %rbp
        xorq    %rbx, %rbx
        movw    $2, x
        movw    $3, n
        movq    $1, j
Mtwo:
        movw    n, x(,j,2)
        incq    j
Mthree:
        cmpq    $500, j
        je      end
Mfour:
        addw    $2, n
Mfive:
        movq    $1, k
Msix:
        movzwl  x(,k,2), pk
        movzwl  n, %eax
        xorq    %rdx, %rdx
        divl    pk
        cmpl    $0, %edx
        je      Mfour
Mseven:
        cmpl    pk, %eax
        jle     Mtwo
Meight:
        incq    k
        jmp     Msix
end:
        xorq    j, j
loop:
        leaq    fmt, %rdi
        movzwl  x(,j,2), %esi
        call    printf
        incq    j
        cmpq    $25, j
        je      bye
        jmp     loop
bye:
        movl    $0, %edi
        callq   exit
        leave
        ret
        .size   main,.-main
        .end

如果将Mthree中的比较减少到25，那么程序就可以了。任何更高的程序，程序在printf中出现故障或挂起。

我正在组装：

cc -static progp.S

我还可以在没有调用printf的情况下添加它，它可以成功地生成前500个素数，这可以从断点到＆＃34; end＆＃34;在gdb。

$ gdb ./a.out
(gdb) b end
Breakpoint 1 at 0x400531
(gdb) run
Starting program: /home/ben/src/hg/asm/knuth/a.out 

Breakpoint 1, 0x0000000000400531 in end ()
(gdb) p $rbx
$1 = 3571

一旦我尝试调用printf，它就会出错，所以我假设我正在做一些愚蠢的事情。

Answer 1

printf在x86-64中期望%rax中的值告诉函数浮点参数的数量。在您的情况下，没有这样的论点，所以清楚%rax（清除%eax也清除%rax）。你的程序似乎运行良好的变化：

...
loop:
        leaq    fmt, %rdi
        movzwl  x(,j,2), %esi
        xor     %eax, %eax
        call    printf
...

分段错误并在汇编代码中挂起

1 个答案: