Question

生成测试似乎很有趣，但我需要生成随机UUID作为测试的一部分。 java.util.UUID / newRandom在test.check收缩方面效果不佳。

java代码如下：

public static UUID randomUUID()
{
  long lsb = r.nextLong();
  long msb = r.nextLong();

  lsb &= 0x3FFFFFFFFFFFFFFFL;
  lsb |= 0x8000000000000000L; // set top two bits to variant 2

  msb &= 0xFFFFFFFFFFFF0FFFL;
  msb |= 0x4000; // Version 4;

  return new UUID( msb, lsb );
}

翻译成Clojure比看起来更难。

如何在Clojure中编写可以成功缩小的随机UUID函数？

Answer 1

fn需要两个long并生成一个合适的类型4 UUID：

(defn make-uuid [[msb lsb]]
  (java.util.UUID. (-> msb
                   (bit-clear 15)
                   (bit-set   14)
                   (bit-clear 13)
                   (bit-clear 12))
               (-> lsb
                   (bit-set   63)
                   (bit-clear 62))))

您可以使用正则表达式检查结果，（首先需要将其转换为字符串）。

(def uuid-v4-regex
     #"(?i)[a-f0-9]{8}-[a-f0-9]{4}-4[a-f0-9]{3}-[98ab][a-f0-9]{3}-[a-f0-9]{12}")

然后你可以测试它如下：

(def uuids (gen/fmap make-uuid (gen/tuple (gen/choose 0 Long/MAX_VALUE)
                                          (gen/choose 0 Long/MAX_VALUE))))

(defspec check-random-uuid 100000
  (for-all [uuid uuids]
       (re-find uuid-v4-regex (str uuid))))

测试看起来像：

(check-random-uuid)
=> {:result true, :num-tests 100000, :seed 1422050154338}

为了好玩，我删除了第二个字段的一个有效字符（9），这就是失败测试的样子，所以你可以看到如何缩小：失败：最小可以帮助。

(pp/pprint (check-random-uuid))
{:result nil,
 :seed 1422050276824,
 :failing-size 2,
 :num-tests 3,
 :fail [#uuid "2c6d1442-eec3-4800-972e-02905c1b3c00"],
 :shrunk
 {:total-nodes-visited 932,
  :depth 29,
  :result nil,
  :smallest [#uuid "00000000-0000-4000-9000-000000000000"]}}

它显示了您可以从测试用例中删除多少噪音。

Answer 2

从test.check版本0.9.0开始，内置gen/uuid会生成不缩小的随机uuids。

如果你真的想缩小UUID，那么generate-two-longs方法也会更容易，因为新的gen/large-integer将生成所有长整数，但不是均匀分布。

仍然没有内置生成器可以在所有长度上生成均匀分布，但我认为这是将来应该添加的内容。

如何生成可以在Clojure中使用test.check的UUID

2 个答案: