Question

我正在研究一个Rails模板，并试图编写一些代码，允许我填充一个表或多列ul标签“从上到下”和“从左到右”然而不是很多我指定的列。我刚刚掌握了Ruby，所以我无法理解这一点。我也对这个有用的片段的惯用Haskell版本感到好奇。对Clojure版本的改进表示赞赏：

(defn table [xs & {:keys [cols direction]
                   :or   {cols 1 direction 'right}}]
  (into []
        (condp = direction
          'down (let [c (count xs)
                      q (int (/ c cols))
                      n (if (> (mod c q) 0) (inc q) q)]
                  (apply map vector (partition n n (repeat nil) xs)))
          'right (map vec (partition cols cols (repeat nil) xs)))))

使用这段代码，我可以执行以下操作：

(table (range 10) :cols 3)

打印出来的情况如下：

0    1    2 
3    4    5 
6    7    8
9

更棘手的一个：

(table (range 10) :cols 3 :direction 'down)

看起来像这样：

0    4    8    
1    5    9    
2    6        
3    7

Answer 1

我无法读取clojure代码（我从未使用过该语言），但基于这些示例，我将在Ruby中执行此操作。

def table array, cols, direction
   if direction==:down
      if array.size%cols != 0
         array[(array.size/cols+1)*cols-1]=nil
         #putting nil in the last space in the array
         #also fills all of the spaces before it
      end
      newarray=array.each_slice(array.size/cols).to_a
      table newarray.transpose.flatten(1), cols, :across
   elsif direction==:across
      array.each_slice(cols) do |row|
         puts row.join("  ")
      end
   else
      raise ArgumentError
   end
end

Answer 2

我可能会在Haskell中使用Hackage中的Data.List.Split包编写类似的东西：

import Data.List       (intercalate, transpose)
import Data.List.Split (splitEvery)

data Direction = Horizontal | Vertical deriving (Eq, Read, Show)

table :: Direction -> Int -> [a] -> [[a]]
table Horizontal cols xs = splitEvery cols xs
table Vertical   cols xs = let (q,r) = length xs `divMod` cols
                               q'    = if r == 0 then q else q+1
                           in transpose $ table Horizontal q' xs

showTable :: Show a => [[a]] -> String
showTable = intercalate "\n" . map (intercalate "\t" . map show)

main :: IO ()
main = mapM_ putStrLn [ showTable $ table Horizontal 3 [0..9]
                      , "---"
                      , showTable $ table Vertical   3 [0..9] ]

其中一些内容，如Direction类型和transpose技巧，源于jkramer的回答。我不会在Haskell中使用关键字参数这样的东西（它实际上并没有这样的东西，但你可以使用Edward Kmett的答案中的记录来模拟它们），但是我把这些参数放在第一位，因为它对部分应用更有用（defaultTable = table Horizontal 1）。 splitEvery函数只是将列表分块到适当大小的列表中;其余的代码应该是直截了当的。 table函数返回列表列表;要获取字符串，showTable函数会插入制表符和换行符。（intercalate函数连接列表列表，用给定列表分隔它们。它类似于Perl / Python / Ruby的join，仅用于列表而不仅仅是字符串。）

Answer 3

这是我在Haskell中快速入侵的内容。我确定它有问题，可以进行优化，但这是开始的事情：

import System.IO
import Data.List

data Direction = Horizontal | Vertical

main = do
    putStrLn $ table [1..9] 3 Horizontal
    putStrLn "---"
    putStrLn $ table [1..9] 3 Vertical


table xs ncol direction =
    case direction of
        Horizontal -> format (rows strings ncol)
        Vertical -> format (columns strings ncol)
    where
        format = intercalate "\n" . map (intercalate " ")

        strings = map show xs

        rows xs ncol =
            if length xs > ncol
                then take ncol xs : rows (drop ncol xs) ncol
                else [xs]

        columns xs = transpose . rows xs

输出：

Answer 4

我的红宝石溶液

def table(values)
  elements = values[:elements]
  cols = values[:cols]
  rows = (elements.count / cols.to_f).ceil

  erg = []

  rows.times do |i|
    cols.times do |j|
      erg << elements[values[:direction] == 'down' ? i+(rows*j) : j+i*(rows-1)]
      if erg.length == cols
        yield erg
        erg = []
      end        
    end
  end
  yield erg
end

用法和输出：

table(:elements => [0,1,2,3,4,5,6,7,8,9], :cols => 3) do |h,i,j|
  puts h.to_s << " " << i.to_s << " " << j.to_s
end

puts "---"

table(:elements => [0,1,2,3,4,5,6,7,8,9], :cols => 3, :direction => "down") do |h,i,j|
  puts h.to_s << " " << i.to_s << " " << j.to_s
end

0 1 2
3 4 5
6 7 8
9  
---
0 4 8
1 5 9
2 6 
3 7

Answer 5

切片和压缩提供了一个简单的Ruby解决方案：

 def table(range, cols, direction=:right)
   if direction == :right
     range.each_slice cols
   else
     columns = range.each_slice((range.to_a.length - 1) / cols + 1).to_a
     columns[0].zip *columns[1..-1]
   end
 end


 puts table(0..9, 3, :down).map { |line| line.join ' ' }

Answer 6

import Data.Array

stride :: Int -> Int -> Int
stride count cols = ceiling (fromIntegral count / fromIntegral cols)

type Direction = Int -> Int -> Int -> Int -> Int

right :: Direction
right count cols x y = y * cols + x

down :: Direction
down count cols x y = x * stride count cols + y

data Options = Options { cols :: Int, direction :: Direction }

options :: Options
options = Options 1 right

table :: Options -> [a] -> Array (Int,Int) (Maybe a)
table (Options cols dir) xs
    = listArray newRange (map f (range newRange))
    where count = length xs
          rows = stride count cols
          newRange = ((0,0),(rows-1,cols-1))
          f (y, x) 
              | ix < count = Just (xs !! ix)
              | otherwise = Nothing
              where ix = dir count cols x y

这为我们提供了一个相当惯用的近似原始查询，并带有可选参数：

*Main> table options { cols = 3 } [1..10]
listArray ((0,0),(3,2)) [Just 1, Just 2, Just 3
                        ,Just 4, Just 5, Just 6
                        ,Just 7, Just 8, Just 9
                        ,Just 10,Nothing,Nothing]

*Main> table options { direction = down, cols = 3 } [1..10]
listArray ((0,0),(3,2)) [Just 1,Just 5,Just 9
                        ,Just 2,Just 6,Just 10
                        ,Just 3,Just 7,Nothing
                        ,Just 4,Just 8,Nothing]

我将中间结果保留为数组形式，因为您已表明他们计划将它们格式化为表格或ul标签。

你会如何在Ruby和/或Haskell中编写这个Clojure片段？

6 个答案: