Question

我需要使用Perl替换HTML中的一些标签：

我有这个：

<span class="a">text</span><span class="a">text</span><span id="b">text</span>

我需要这样，span标记class=a的标记改为b标记：

<b>text</b><b>text</b><span id="b">text</span>

我尝试使用HTML::Manipulator但未成功。

Answer 1

以下是如何使用HTML :: TreeBuilder：

use strict;
use warnings;
use HTML::TreeBuilder;

my $html_string = '<span class="a">text</span><span class="a">text</span><span id="b">text</span>';    

my $root = HTML::TreeBuilder->new_from_content($html_string);
$root->elementify;  # Make $root into an HTML::Element object;


for my $e ( $root->look_down( _tag => 'span', class => 'a' ) ) {
    $e->tag( 'b' );
    $e->attr( class => undef );
} 

print $root->as_HTML;

Answer 2

使用HTML::Parser的示例：

#! /usr/bin/perl

use warnings;
use strict;
use HTML::Parser;
my $p = HTML::Parser->new( api_version => 3,
  start_h => [\&start, "tagname, attr, text, skipped_text"],
  end_h   => [\&end,   "tagname,       text, skipped_text"],
);
$p->parse_file(\*DATA);

my @switch_span_end;
sub start {
  my($tag,$attr,$text,$skipped) = @_;
  print $skipped;
  unless ($tag eq 'span' && ($attr->{class}||"") eq "a") {
    print $text;
    return;
  }
  push @switch_span_end => 1;
  print "<b>";
}

sub end {
  my($tag,$text,$skipped) = @_;
  print $skipped;
  if (@switch_span_end && $tag eq "span") {
    print "</b>";
    pop @switch_span_end;
  }
  else {
    print $text;
  }
}
__DATA__
<span class="a">text</span><span class="a">text</span><span id="b">text</span>

输出：

<b>text</b><b>text</b><span id="b">text</span>

Answer 3

我会使用HTML::Tree来解析HTML，然后找到具有所需属性的节点，更改它们，然后输出新树，这将具有您想要的更改。

如何在Perl中基于类替换一些HTML标记？

3 个答案: