Question

我有一个弹出菜单，其中包含多个菜单项，其中一个菜单项可以包含子项。此条目右侧有一个小箭头，当您悬停鼠标悬停在其上时，将打开一个子菜单（不单击）。现在我想在运行时填充此子菜单，但前提是用户实际打开它。如果用户从未打开子菜单，则它将为空（可能包含占位符）。我怎么能做到这一点？甚至可以在弹出菜单可见时修改它？

感谢您的帮助！

Answer 1

标准菜单或上下文（弹出）菜单中的子菜单之间没有区别：如果菜单项附加了子菜单，则其OnClick事件将在子菜单显示之前触发（请注意，您不要需要单击才能显示），在该事件处理程序中，您可以修改子菜单（设置现有项的属性，或添加新项/删除现有项）。

有关动态添加和删除项目的一些演示代码：

procedure TForm1.FormCreate(Sender: TObject);
var
  Popup: TPopupMenu;
  Item, SubItem: TMenuItem;
begin
  Popup := TPopupMenu.Create(Self);
  PopupMenu := Popup;
  Item := TMenuItem.Create(Popup);
  Item.Caption := 'Test submenu';
  Item.OnClick := PopupClick;
  Popup.Items.Add(Item);

  SubItem := TMenuItem.Create(Item);
  SubItem.Caption := 'dummy';
  Item.Add(SubItem);
end;

procedure TForm1.PopupClick(Sender: TObject);
var
  SubmenuItem, Item: TMenuItem;
begin
  SubmenuItem := Sender as TMenuItem;
  // delete old items (leave at least one to keep the submenu)
  while SubmenuItem.Count > 1 do
    SubmenuItem.Items[SubmenuItem.Count - 1].Free;
  // create new items
  while SubmenuItem.Count < 3 do begin
    Item := TMenuItem.Create(SubmenuItem);
    Item.Caption := Format('new item created %d', [GetTickCount]);
    SubmenuItem.Add(Item);
  end;
end;

如何检测弹出菜单子菜单的弹出窗口（以及如何动态填充它）？

1 个答案: