Question

为什么我处于无限循环中？

PROGRAM tayls
  USE kertoma
  USE tforexp
  IMPLICIT NONE
  INTEGER :: n= 5
  INTEGER :: i
  REAL :: x
  WRITE(*,*) "f1(x)= (e**x-1)/x"
  DO i=1,10
    x= 0.01*i
    WRITE(*,*)x, (taylexp(x,n)-1)/x
  END DO
END PROGRAM tayls

带

MODULE tforexp
  USE kertoma
  IMPLICIT NONE
    CONTAINS
      FUNCTION taylexp(x,ord)
        REAL :: taylexp, x, sum
        INTEGER :: ord, i
        sum= 1.0
        DO i=1,ord
          sum= sum+ x**i/fact(i)
        END DO
        taylexp= sum
      END FUNCTION taylexp
END MODULE tforexp

和

MODULE kertoma
  IMPLICIT NONE
CONTAINS
  FUNCTION fact(n)
    INTEGER :: fact,n,y=1
    DO WHILE (n>1)
      y= y*n
      n= n-1
    END DO
    fact = y
  END FUNCTION fact
END MODULE kertoma

无限循环在第一次打印“f1（x）= ...”后立即开始。所以我认为它第一次调用taylexp函数时会进入无限循环，但我不明白为什么。我认为它与使用公共变量的fortran有关，但我无法如何始终如一地避免这种情况。首先我尝试调用函数而不定义x，只使用“0.01 * i”，我想可能问题是这个函数对虚拟索引使用了相同的名称，但显然它没有解决问题。

Answer 1

问题出在函数fact(n)：

之内

n= n-1

更改参数，因此更改i中的循环计数器taylexp。在您的代码中i永远不会超过2。我很惊讶编译器没有发出警告（我也没有发出警告），因为在这种情况下可能会发生任何事情。

更好地指定虚拟参数的intent以避免将来出现这样的问题：

  FUNCTION fact(n)
    integer,intent(in)  :: n
    INTEGER :: fact,nn,y

    y=1 ! Avoid the implicit save and assign variables separately
    nn=n
    DO WHILE (nn>1)
      y= y*nn
      nn= nn-1
    END DO
    fact = y
  END FUNCTION fact

Answer 2

使用gfortran，可以捕获此错误 -fcheck = all选项：

$ gfortran -fcheck=all 1.f90 
$ ./a.out
 f1(x)= (e**x-1)/x
At line 22 of file 1.f90
Fortran runtime error: Loop variable has been modified

调用函数时Fortran无限循环

2 个答案: