Question

与this question about iterating over subroutine references类似，并且由于回答了this question about a OO dispatch table，我想知道如何在引用中调用方法引用，而不首先删除它，或者甚至可能。

例如：

package Class::Foo;
use 5.012;   #Yay autostrict!
use warnings;

# a basic constructor for illustration purposes....
sub new { 
    my $class = shift;
    return bless {@_}, $class;
}

# some subroutines for flavor...
sub sub1 { say 'in sub 1'; return shift->{a} }
sub sub2 { say 'in sub 2'; return shift->{b} }
sub sub3 { say 'in sub 3'; return shift->{c} }

# and a way to dynamically load the tests we're running...
sub sublist {
    my $self = shift; 
    return [
        $self->can('sub1'),
        $self->can('sub3'),
        $self->can('sub2'),
    ];
}

package main;

sub get_index { ... } # details of how we get the index not important    

my $instance = Class::Foo->new(a => 1, b => 2, c => 3);
my $subs = $instance->sublist();
my $index = get_index();

# <-- HERE

所以，在HERE，我们可以做到：

my $ref = $subs->[$index];
$instance->$ref();

但是我们如何在不删除引用的情况下执行此操作？

编辑：

更改了代码示例，以便人们不会对实现细节感到困惑（叹息，尽我所能）。我和第一个链接之间的重要区别是该函数应该作为方法调用，而不是作为直接子例程调用。

编辑2：

请参阅discussion in the linked comment有关技术细节的信息，以及为什么更长的方法（将subref存储到变量，然后调用它）可能更可取。

Answer 1

如上所述，你可以逃脱

$tests->[$index]();

因为您问题中的方法未使用$self。

您可以明确地传递$instance，但这很笨拙。更好的方法是使用闭包来模拟代理：

sub sublist {
    my $self = shift;
    my $sublist;
    for (qw/ sub1 sub3 sub2 /) {
      my $meth = $_;
      push @$sublist => sub { $self->$meth() };
    }
    return $sublist;
}

如果您想简明扼要，请使用

sub sublist {
    my $self = shift;
    return [ map { my $meth = $_; sub { $self->$meth() } }
             qw/ sub1 sub3 sub2 / ];
}

随机调用一个

$tests->[$index]();

但现在这些方法会获得调用。

更新

通过can抓取子参数似乎是不必要的复杂性。如果运行时确定要调用的方法名称列表，则可以大大简化代码：

sub sublist {
    my $self = shift; 
    return [ qw/ sub1 sub3 sub2 / ];
}

下面，我们将它们全部称为测试目的，但您也可以看到如何只调用一个：

foreach my $method (@$subs) {
  my $x = $instance->$method();
  say "$method returned $x";
}

输出：

in sub 1
sub1 returned 1
in sub 3
sub3 returned 3
in sub 2
sub2 returned 2

Answer 2

（临时占位符在此处，除非答案的原始海报返回）：

诀窍是添加一个解除引用：

$instance->${\$sublist->[$index]}(@args);

因此你也可以这样做：

$instance->${\$instance->sublist->[$index]}(@args);

否则它认为这是一个取消引用的标量。（例如，Not a SCALAR reference at script.pl, line XX）。

如何在数组引用中使用索引作为Perl中的方法引用？

2 个答案:

更新