gnuplot - 格式化图表的标题（字母栏）

Question

我想制作一个gnuplot，其中包含一个情节标题中栏上的字母。图像显示了这样的尝试：

产生它的代码如下（我将这些行粘贴到Windows 7中的 gnuplot窗口）：

set terminal pdf enhanced
set output "C:/linMitSaett.pdf"
set grid ytics lt 0 lw 1 lc rgb "#D3D3D3"
set grid xtics lt 0 lw 1 lc rgb "#D3D3D3"
set yrange [0:800]
set xlabel "Zeiteinheit {/Symbol t}" 
set ylabel "#Individuen  p({/Symbol t})"
set label "p_0=2" textcolor rgb "red" at 4,300
set label "p_0=400" textcolor rgb "blue" at 1,425
set label "p_0=800" textcolor rgb "green" at 4,510
set label "{/Symbol l}_0=200 (Wachstumsrate)\n{/Symbol l}_1=0.5 (Bremsrate)" at 4,160
plot [0:10] 400+(2-400)*exp(-0.5*x) title "p_0 < ~p{.7-}", 400+(800-400)*exp(-0.5*x) title "p_0 > ~p{.7-}", 400+(400-400)*exp(-0.5*x) title "p_0 = ~p{.7-}"
set output "C:/deleteme.pdf"
reset

如何将线垂直向下移动，以便它们与每个p对齐，而不是与每个p上的条对齐？

Answer 1

如果您将set encoding utf8添加到文件中，则只需在标签中使用上划线字符（U + 203E）即可。这样就无需为角色添加偏移量：

plot [0:10] 400+(2-400)*exp(-0.5*x) title "p_0 < ~p‾", \
            400+(800-400)*exp(-0.5*x) title "p_0 > ~p‾", \
            400+(400-400)*exp(-0.5*x) title "p_0 = ~p‾"

如果在编辑器中无法输入上划线符号，您还可以使用八进制代码作为UTF-8字符：

plot [0:10] 400+(2-400)*exp(-0.5*x) title "p_0 < ~p\342\200\276", \
            400+(800-400)*exp(-0.5*x) title "p_0 > ~p\342\200\276", \
            400+(400-400)*exp(-0.5*x) title "p_0 = ~p\342\200\276"