Question

我正在编写一个创建名称数据库的脚本，这个数据库有不同的版本。我的脚本将版本作为输入（如果没有输入，它有一个默认版本）每个数据库版本都基于previouse版本，但包含一些其他名称。

我试图找到一种方法来定义我的数组中的某些输入作为iversion的函数。因此我使用像verilog IFDEF

这样的东西

例如：

my @DATABASE = (
  "Arik",
  "Ben",

  if ($version = 1.3) {
    "Suzie",
    "Dan",
  }

  "Roth"
);

在这个例子中，名称Arik，Ben和Roth将在所有版本的数据库中，但Suzie和Dan将只在1.3版数据库中

有没有好方法呢？

Answer 1

my @DATABASE = (
   "Arik",
   "Ben",
   $version == 1.3 ? "Suzie" : (),
   $version == 1.3 ? "Dan" : (),
   "Roth",
);

或

my @DATABASE = (
   "Arik",
   "Ben",
   ( $version == 1.3 ? (
      "Suzie",
      "Dan",
   ) : () ),
   "Roth",
);

或

sub cond { my $cond = shift; return $cond ? @_ : () }

my @DATABASE = (
   "Arik",
   "Ben",
   cond($version == 1.3,
      "Suzie",
      "Dan",
   ),
   "Roth",
);

或

my @DATABASE = (
   "Arik",
   "Ben",
   ( "Suzie" ) x $version == 1.3,
   ( "Dan"   ) x $version == 1.3,
   "Roth",
);

或

my @DATABASE = (
   "Arik",
   "Ben",
);
if ($version == 1.3) {
   push @DATABASE, (
      "Suzie",
      "Dan",
   );
}
push @DATABASE, (
   "Roth",
);

或

my @DATABASE;
push @DATABASE, "Arik";
push @DATABASE, "Ben";
push @DATABASE, "Suzie" if $version == 1.3;
push @DATABASE, "Dan"   if $version == 1.3;
push @DATABASE, "Roth";

Answer 2

不清楚你想要什么，但这可能会有所帮助

use strict;
use warnings;

use Data::Dump;

my $version = '1.3';

my @database = (
    "Arik",
    "Ben",
    $version eq '1.3' ? (
      "Suzie",
      "Dan",
    ) : (),
    "Roth",
);

dd \@database;

<强>输出

["Arik", "Ben", "Suzie", "Dan", "Roth"]

Answer 3

是的，您可以使用Ternary Conditional operator：

my @DATABASE = (
   "Arik",
   "Ben",
   $version == 1.3 ? ("Suzie", "Dan") : (),             
   "Roth"
);

使用perl在'ifdef下创建数组字段

3 个答案: