Question

我对List.fold和List.foldBack之间差异的理解是，foldBack以相反的顺序迭代其列表。这两个函数都会累积列表中项目的结果。

我遇到一个很好的例子，我最好将foldBack放在列表上。在我提出的示例中，如果函数逻辑执行相同的操作，则fold和foldBack的结果相同。

[<Fact>]
let ``List.foldBack accumulating a value from the right to the left``() =
    let list = [1..5]       
    let fFoldBack x acc =
        acc - x

    let fFold acc x =
        acc - x

    let foldBackResult = List.foldBack fFoldBack list 0
    let foldResult = List.fold fFold 0 list

    Assert.Equal( -15, foldBackResult ) //  0 - 5 - 4 - 3 - 2 - 1
    Assert.Equal( -15, foldResult ) //      0 - 1 - 2 - 3 - 4 - 5

Answer 1

您在示例中看不出有什么不同，因为您选择的功能适用于任何x1和x2：

(acc - x1) - x2 = (acc - x2) - x1

因此，按照您通过列表的顺序无关紧要，您将获得相同的结果。

列表构造是函数的一个示例，但不是这样：

x1 :: (x2 :: acc) <> x2 :: (x1 :: acc)

因此，以下结果会产生不同的结果：

List.fold (fun acc x -> x :: acc) [] [1; 2; 3; 4; 5]
// val it : int list = [5; 4; 3; 2; 1]

List.foldBack (fun x acc -> x :: acc) [1; 2; 3; 4; 5] [];;
// val it : int list = [1; 2; 3; 4; 5]

List.fold以空结果列表开头，然后继续输入，将每个元素添加到结果列表的前面;因此最终结果的顺序相反。

另一方面，

List.foldBack向后通过输入;所以新添加到结果列表前面的每个元素本身都在原始列表的前面。所以最终结果与原始列表相同。

Answer 2

Tarmil的答案已经以良好，简洁的方式证明了两者之间的差异。我将给出一个使用更复杂的数据类型的示例。（实际上，如果你忽略命名，那么我的示例是一个链表，但你可以想象它如何扩展到更复杂的东西。）

当您计算标量值时，fold与foldBack的目的不一定明显，但当您开始使用它来构建数据结构时，很明显大多数此类结构必须建在一个特定的方向。如果使用不可变数据结构，则尤其如此，因为您没有选择构造节点，然后将其更新为指向另一个节点。

在这个例子中，我为一个简单的编程语言定义了一个结构，除了打印数字之外什么都不做。它会识别两条指令Print和End。每个打印指令存储指向下一指令的指针。因此，程序由一系列指令组成，每个指令指向下一个指令。（我使用这个特定示例的原因是，通过执行程序，您可以演示其结构。）

程序使用三种不同的方法从整数列表构造程序。第一个make_list_printer是递归定义的，没有折叠，以展示我们想要实现的目标。第二个make_list_printer_foldBack使用foldBack来获得相同的结果。第三个make_list_printer_fold使用fold来演示它是如何产生错误结果的。

我主要使用OCaml编码，而不是F＃，所以如果下面使用的某些编码约定在F＃中没有被认为是合适的样式，我会道歉。不过，我确实在F＃解释器中进行了测试，但它确实有效。

(* Data structure of our mini-language. *)
type prog =
| End
| Print of int * prog

(* Builds a program recursively. *)
let rec make_list_printer = function
| [] -> End
| i :: program -> Print (i, make_list_printer program)

(* Builds a program using foldBack. *)
let make_list_printer_foldBack ints =
  List.foldBack (fun i p -> Print (i, p)) ints End

(* Builds a program in the wrong direction. *)
let make_list_printer_fold ints =
  List.fold (fun p i -> Print (i, p)) End ints

(* The interpreter for our mini-language. *)
let rec run_list_printer = function
| End ->
    printfn ""
| Print (i, program) ->
    printf "%d " i;
    run_list_printer program

(* Build and run three different programs based on the same list of numbers. *)
let () =
  let base_list = [1; 2; 3; 4; 5] in
  let a =  make_list_printer           base_list  in
  let b =  make_list_printer_foldBack  base_list  in
  let c =  make_list_printer_fold      base_list  in
  run_list_printer a;
  run_list_printer b;
  run_list_printer c

运行时得到的输出是：

1 2 3 4 5
1 2 3 4 5
5 4 3 2 1

List.fold和List.foldBack之间的区别示例

2 个答案: