Question

每个元素都应该相互配对，但只能配对一次。

给定列表A, B, C我想制作以下对列表：(A,B), (A,C), (B,C)

同样，对于4个元素A, B, C, D，结果应为(A,B), (A,C), (A,D), (B,C), (B,D), (C,D)。

我尝试使用eachPermutation，eachCombintation但是找不到好方法。如果您告诉我这项操作的主要名称是什么，那将是一个很大的帮助。

Answer 1

Groovy中可能没有这样的功能，但你可以很容易地实现它：

def pairs(def elements) {
    return elements.tail().collect { [elements.head(), it] } + (elements.size() > 1 ? pairs(elements.tail()) : [])
}

assert pairs(['A', 'B', 'C']) == [['A', 'B'], ['A', 'C'], ['B', 'C']]
assert pairs(['A', 'B', 'C', 'D']) == [['A', 'B'], ['A', 'C'], ['A', 'D'], ['B', 'C'], ['B', 'D'], ['C', 'D']]

Answer 2

您可以使用combinations，toSet，sort和findAll其余尺寸等于2的其他人：

def uniqueCombinations = { l ->
  [l,l].combinations()*.toSet()*.sort().unique().findAll { it.size() == 2 }
}

l=[1,2,3]
assert uniqueCombinations(l) == [[1, 2], [1, 3], [2, 3]]

Answer 3

有点晚，但似乎subsequences会很快解决这个问题。它提供的不仅仅是对，但限制结果集对于未来的读者来说是微不足道的：

def pairs(def l) {
  l.subsequences().findAll {it.size() == 2}
}
assert pairs(['a','b','c']) == [['a','b'], ['a','c'], ['b', 'c']] as Set
assert pairs(['a', 'b', 'c', 'd']) == [['a', 'b'], ['a', 'c'], ['a', 'd'], ['b', 'c'], ['b', 'd'], ['c', 'd']] as Set

Answer 4

使用eachCombination，它将是：

def l = ['A', 'B', 'C', 'D'], result = []

[l, l].eachCombination {
    if ( ! ( it in result*.intersect( it ) || it[0] == it[1] ) ) {
        result << it.reverse()
    }
}

assert result == [
    ['A', 'B'], ['A', 'C'], ['A', 'D'], ['B', 'C'], ['B', 'D'], ['C', 'D']
]

Answer 5

如何递归？第一个元素和尾部的组合，然后递归到列表的其余部分。

def comb(l,r=[]) {
    if (l) {
        r.addAll( [l.head(), l.tail()].combinations() )
        return comb(l.tail(), r)
    }
    return r
}

def m = ['a','b','c','d']
def result = comb(m)
assert result == [['a', 'b'], ['a', 'c'], ['a', 'd'], ['b', 'c'], ['b', 'd'], ['c', 'd']]

groovy方式配对列表中的每个元素

5 个答案: