Question

我有一个varchar @ a ='a | b | c | d | e | f | g | h | i | j | k | l | m | n | o | p'，有|划定的价值观。我想将此变量拆分为数组或表。有没有人对此有所了解。

Answer 1

使用像这样的表值函数

CREATE FUNCTION Splitfn(@String varchar(8000), @Delimiter char(1))       
returns @temptable TABLE (items varchar(8000))       
as       
begin       
    declare @idx int       
    declare @slice varchar(8000)       

    select @idx = 1       
        if len(@String)<1 or @String is null  return       

    while @idx!= 0       
    begin       
        set @idx = charindex(@Delimiter,@String)       
        if @idx!=0       
            set @slice = left(@String,@idx - 1)       
        else       
            set @slice = @String       

        if(len(@slice)>0)  
            insert into @temptable(Items) values(@slice)       

        set @String = right(@String,len(@String) - @idx)       
        if len(@String) = 0 break       
    end   
return      

end

获取变量并使用此函数，

SELECT i.items FROM dbo.Splitfn(@a,'|') AS i

Answer 2

一般来说，这是一个常见的问题

我会给出一个共同的答案：Arrays and Lists in SQL Server 2005 and Beyond作者：Erland Sommarskog

我建议使用table of numbers，而不是循环，以供一般使用。

Answer 3

试试这个：

declare @a varchar(10) 
set @a = 'a|b|c|'
while len(@a) > 1
begin
insert into #temp
select substring(@a,1,patindex('%|%',@a)-1);
set @a = substring(@a,patindex('%|%',@a)+1,len(@a))
end;

Answer 4

这是一种替代的基于XML的解决方案。它似乎具有与Splitfn（）解决方案类似的性能。

这会将varchar a|b|c|d|e|f|g|h|i|j|k|l|m|n|o|p转换为XML <a>a</a><a>b</a><a>c</a><a>d</a><a>e</a><a>f</a><a>g</a><a>h</a><a>i</a><a>j</a><a>k</a><a>l</a><a>m</a><a>n</a><a>o</a><a>p</a>，并从每个XML <a>节点中提取值。

declare @a      varchar(max);
set @a  =   'a|b|c|d|e|f|g|h|i|j|k|l|m|n|o|p';

declare @xml    xml;
set @xml    
    =   '<a>'+replace(replace(replace(@a,'&','&amp;'),'<','&lt;'),'|','</a><a>')+'</a>';

SELECT  x.n.value('.','VARCHAR(1)') AS  singleValue
FROM    @xml.nodes('/a') AS  x(n)
;

如何在T-SQL中拆分字符串？

4 个答案: