Question

我们正在从SQL Server 2005升级到2008.几乎2005实例中的每个数据库都设置为2000兼容模式，但我们跳到2008年。我们的测试已经完成，但我们学到的是我们需要加快速度。

我发现了一些存储过程，既可以从丢失的表中选择数据，也可以尝试使用不存在的ORDER BY列。

包装SQL以在SET PARSEONLY ON中创建过程并在try / catch中捕获错误仅捕获ORDER BY中的无效列。在从丢失表中选择数据的过程中找不到错误。然而，SSMS 2008的intellisense会找到问题，但我仍然可以继续并成功运行ALTER脚本，而不会抱怨它。

那么，为什么我甚至可以创建一个在运行时失败的程序？是否有任何工具可以比我尝试过的更好？

我找到的第一个工具不是很有用：DbValidator from CodeProject，但它找到的问题少于我在SqlServerCentral上找到的脚本，后者发现了无效的列引用。

-------------------------------------------------------------------------
-- Check Syntax of Database Objects
-- Copyrighted work.  Free to use as a tool to check your own code or in 
--  any software not sold. All other uses require written permission.
-------------------------------------------------------------------------
-- Turn on ParseOnly so that we don't actually execute anything.
SET PARSEONLY ON 
GO

-- Create a table to iterate through
declare @ObjectList table (ID_NUM int NOT NULL IDENTITY (1, 1), OBJ_NAME varchar(255), OBJ_TYPE char(2))

-- Get a list of most of the scriptable objects in the DB.
insert into @ObjectList (OBJ_NAME, OBJ_TYPE)
SELECT   name, type
FROM     sysobjects WHERE type in ('P', 'FN', 'IF', 'TF', 'TR', 'V')
order by type, name

-- Var to hold the SQL that we will be syntax checking
declare @SQLToCheckSyntaxFor varchar(max)
-- Var to hold the name of the object we are currently checking
declare @ObjectName varchar(255)
-- Var to hold the type of the object we are currently checking
declare @ObjectType char(2)
-- Var to indicate our current location in iterating through the list of objects
declare @IDNum int
-- Var to indicate the max number of objects we need to iterate through
declare @MaxIDNum int
-- Set the inital value and max value
select  @IDNum = Min(ID_NUM), @MaxIDNum = Max(ID_NUM)
from    @ObjectList

-- Begin iteration
while @IDNum <= @MaxIDNum
begin
  -- Load per iteration values here
  select  @ObjectName = OBJ_NAME, @ObjectType = OBJ_TYPE
  from    @ObjectList
  where   ID_NUM = @IDNum 

  -- Get the text of the db Object (ie create script for the sproc)
  SELECT @SQLToCheckSyntaxFor = OBJECT_DEFINITION(OBJECT_ID(@ObjectName, @ObjectType))

  begin try
    -- Run the create script (remember that PARSEONLY has been turned on)
    EXECUTE(@SQLToCheckSyntaxFor)
  end try
  begin catch
    -- See if the object name is the same in the script and the catalog (kind of a special error)
    if (ERROR_PROCEDURE() <> @ObjectName)
    begin
      print 'Error in ' + @ObjectName
      print '  The Name in the script is ' + ERROR_PROCEDURE()+ '. (They don''t match)'
    end
    -- If the error is just that this already exists then  we don't want to report that.
    else if (ERROR_MESSAGE() <> 'There is already an object named ''' + ERROR_PROCEDURE() + ''' in the database.')
    begin
      -- Report the error that we got.
      print 'Error in ' + ERROR_PROCEDURE()
      print '  ERROR TEXT: ' + ERROR_MESSAGE() 
    end
  end catch

  -- Setup to iterate to the next item in the table
  select  @IDNum = case
            when Min(ID_NUM) is NULL then @IDNum + 1
            else Min(ID_NUM)
          end  
  from    @ObjectList
  where   ID_NUM > @IDNum

end
-- Turn the ParseOnly back off.
SET PARSEONLY OFF 
GO

Answer 1

您可以选择不同的方式。首先，SQL SERVER 2008 支持依赖，它存在于STORED PROCEDURE的DB包含依赖项中（请参阅http://msdn.microsoft.com/en-us/library/bb677214%28v=SQL.100%29.aspx，http://msdn.microsoft.com/en-us/library/ms345449.aspx和http://msdn.microsoft.com/en-us/library/cc879246.aspx）。您可以使用sys.sql_expression_dependencies和sys.dm_sql_referenced_entities查看并验证那里。

但是，验证所有STORED PROCEDURE的最简单方法如下：

导出所有STORED PROCEDURE
删除旧的现有存储过程
导入刚刚导出的STORED PROCEDURE。

如果升级数据库，则不会验证现有存储过程，但如果您创建新存储过程，则将验证该过程。因此，在导出和导出所有存储过程后，您将收到报告的所有现有错误。

您还可以使用如下代码

SELECT definition
FROM sys.sql_modules
WHERE object_id = (OBJECT_ID(N'spMyStoredProcedure'))

更新：要查看存储过程spMyStoredProcedure引用的对象（如表和视图），您可以使用以下命令：

SELECT OBJECT_NAME(referencing_id) AS referencing_entity_name 
    ,referenced_server_name AS server_name
    ,referenced_database_name AS database_name
    ,referenced_schema_name AS schema_name
    , referenced_entity_name
FROM sys.sql_expression_dependencies 
WHERE referencing_id = OBJECT_ID(N'spMyStoredProcedure');

更新2 ：在对我的回答的评论中，Martin Smith建议使用sys.sp_refreshsqlmodule而不是重新创建存储过程。所以使用代码

SELECT 'EXEC sys.sp_refreshsqlmodule ''' + OBJECT_SCHEMA_NAME(object_id) +
              '.' + name + '''' FROM sys.objects WHERE type in (N'P', N'PC')

一个接收脚本，该脚本可用于验证存储过程依赖项。输出将如下所示（使用AdventureWorks2008的示例）：

EXEC sys.sp_refreshsqlmodule 'dbo.uspGetManagerEmployees'
EXEC sys.sp_refreshsqlmodule 'dbo.uspGetWhereUsedProductID'
EXEC sys.sp_refreshsqlmodule 'dbo.uspPrintError'
EXEC sys.sp_refreshsqlmodule 'HumanResources.uspUpdateEmployeeHireInfo'
EXEC sys.sp_refreshsqlmodule 'dbo.uspLogError'
EXEC sys.sp_refreshsqlmodule 'HumanResources.uspUpdateEmployeeLogin'
EXEC sys.sp_refreshsqlmodule 'HumanResources.uspUpdateEmployeePersonalInfo'
EXEC sys.sp_refreshsqlmodule 'dbo.uspSearchCandidateResumes'
EXEC sys.sp_refreshsqlmodule 'dbo.uspGetBillOfMaterials'
EXEC sys.sp_refreshsqlmodule 'dbo.uspGetEmployeeManagers'

Answer 2

这对我有用：

-- Based on comment from http://blogs.msdn.com/b/askjay/archive/2012/07/22/finding-missing-dependencies.aspx
-- Check also http://technet.microsoft.com/en-us/library/bb677315(v=sql.110).aspx

select o.type, o.name, ed.referenced_entity_name, ed.is_caller_dependent
from sys.sql_expression_dependencies ed
join sys.objects o on ed.referencing_id = o.object_id
where ed.referenced_id is null

您应该获得SP的所有缺失依赖项，解决后期绑定的问题。

异常：is_caller_dependent = 1并不一定意味着依赖性受损。它只是意味着依赖关系在运行时解析，因为未指定引用对象的模式。您可以避免它指定引用对象的架构（例如另一个SP）。

致Jay's blog和匿名评论者的信用......

Answer 3

我喜欢使用显示预估执行计划。它合理地突出了许多错误，而无需真正运行proc。

Answer 4

我在之前的项目中遇到了同样的问题，并在SQL2005上编写了TSQL checker，后来在Windows program上实现了相同的功能。

Answer 5

当我遇到这个问题时，我有兴趣找到一种安全，非侵入性和快速的技术来验证语法和对象（表，列）引用。

虽然我同意实际执行每个存储过程可能会产生更多问题而不仅仅是编译它们，但必须谨慎对待前一种方法。也就是说，您需要知道实际上执行每个存储过程是安全的（例如，它是否会擦除某些表？）。这个安全问题可以通过将执行包装在事务中并将其回滚来解决，因此没有任何更改是永久性的，正如devio的回答中所建议的那样。尽管如此，这种方法可能需要相当长的时间，具体取决于您操作的数据量。

问题中的代码以及Oleg的答案的第一部分都建议重新实例化每个存储过程，因为该操作重新编译过程并执行此类语法验证。但这种方法是侵入性的 - 它对于私人测试系统来说很好，但可能会破坏其他开发人员在大量使用的测试系统上的工作。

我遇到了文章Check Validity of SQL Server Stored Procedures, Views and Functions，它提供了一个.NET解决方案，但是底部的follow-up post“ddblue”让我更感兴趣。此方法获取每个存储过程的文本，将create关键字转换为alter以便可以编译，然后编译proc。并且准确地报告任何不良的表和列引用。代码运行，但由于创建/更改转换步骤，我很快遇到了一些问题。

从“创建”到“更改”的转换查找由单个空格分隔的“CREATE”和“PROC”。在现实世界中，可能存在空格或制表符，并且可能存在一个或多个。我添加了一个嵌套的“替换”序列（感谢Jeff Moden的this article！）将所有这些事件转换为单个空格，允许转换按原设计进行。然后，由于需要在使用原始“sm.definition”表达式的任何地方使用它，我添加了一个公用表表达式，以避免大规模，难看的代码重复。所以这是我更新的代码版本：

DECLARE @Schema NVARCHAR(100),
    @Name NVARCHAR(100),
    @Type NVARCHAR(100),
    @Definition NVARCHAR(MAX),
    @CheckSQL NVARCHAR(MAX)

DECLARE crRoutines CURSOR FOR
WITH System_CTE ( schema_name, object_name, type_desc, type, definition, orig_definition)
AS -- Define the CTE query.
( SELECT    OBJECT_SCHEMA_NAME(sm.object_id) ,
            OBJECT_NAME(sm.object_id) ,
            o.type_desc ,
            o.type,
            REPLACE(REPLACE(REPLACE(LTRIM(RTRIM(REPLACE(sm.definition, char(9), ' '))), '  ', ' ' + CHAR(7)), CHAR(7) + ' ', ''), CHAR(7), '') [definition],
            sm.definition [orig_definition]
  FROM      sys.sql_modules (NOLOCK) AS sm
            JOIN sys.objects (NOLOCK) AS o ON sm.object_id = o.object_id
  -- add a WHERE clause here as indicated if you want to test on a subset before running the whole list.
  --WHERE     OBJECT_NAME(sm.object_id) LIKE 'xyz%'
)
-- Define the outer query referencing the CTE name.
SELECT  schema_name ,
        object_name ,
        type_desc ,
        CASE WHEN type_desc = 'SQL_STORED_PROCEDURE'
             THEN STUFF(definition, CHARINDEX('CREATE PROC', definition), 11, 'ALTER PROC')
             WHEN type_desc LIKE '%FUNCTION%'
             THEN STUFF(definition, CHARINDEX('CREATE FUNC', definition), 11, 'ALTER FUNC')
             WHEN type = 'VIEW'
             THEN STUFF(definition, CHARINDEX('CREATE VIEW', definition), 11, 'ALTER VIEW')
             WHEN type = 'SQL_TRIGGER'
             THEN STUFF(definition, CHARINDEX('CREATE TRIG', definition), 11, 'ALTER TRIG')
        END
FROM    System_CTE
ORDER BY 1 , 2;

OPEN crRoutines

FETCH NEXT FROM crRoutines INTO @Schema, @Name, @Type, @Definition

WHILE @@FETCH_STATUS = 0 
    BEGIN
        IF LEN(@Definition) > 0
            BEGIN
                -- Uncomment to see every object checked.
                -- RAISERROR ('Checking %s...', 0, 1, @Name) WITH NOWAIT
                BEGIN TRY
                    SET PARSEONLY ON ;
                    EXEC ( @Definition ) ;
                    SET PARSEONLY OFF ;
                END TRY
                BEGIN CATCH
                    PRINT @Type + ': ' + @Schema + '.' + @Name
                    PRINT ERROR_MESSAGE() 
                END CATCH
            END
        ELSE
            BEGIN
                RAISERROR ('Skipping %s...', 0, 1, @Name) WITH NOWAIT
            END
        FETCH NEXT FROM crRoutines INTO @Schema, @Name, @Type, @Definition
    END

CLOSE crRoutines
DEALLOCATE crRoutines

Answer 6

在我首次提出这个问题的九年后，我刚刚发现了一个由Microsoft自己构建的出色工具，它不仅可以可靠地验证SQL Server版本之间的存储过程兼容性，而且还可以验证所有其他内部方面。它已被重命名了几次，但他们目前称之为：

Microsoft®数据迁移助手v4.2

https://www.microsoft.com/en-us/download/details.aspx?id=53595

数据迁移助手（DMA）使您能够通过检测可能影响新版本SQL Server上的数据库功能的兼容性问题来升级到现代数据平台。它建议针对您的目标环境提高性能和可靠性。它不仅使您可以将架构和数据移动，而且可以将不包含对象从源服务器移动到目标服务器。

上面使用EXEC sys.sp_refreshsqlmodule的答案是一个很好的开始，但是在2008 R2上运行它时，我们遇到了一个主要问题：任何重命名的存储过程或函数（使用sp_rename，而不是DROP / CREATE模式）在运行刷新过程后恢复为先前的定义，因为内部元数据未使用新名称刷新。这是一个已知的错误，已在SQL Server 2012中修复，但此后我们度过了愉快的一天。（未来的读者，一种解决方法是，如果刷新引发错误，则发出ROLLBACK。）

无论如何，时代变了，新工具可用-以及那样的好工具-因此这个答案的添加太晚了。

验证T-SQL存储过程的可靠方法

6 个答案:

Microsoft®数据迁移助手v4.2