在linux bash中反向文件行顺序但是每个3行的块

Question

我想反转一个文件但是在这个文件中我记录了3行

a1
a2
a3
...
x1
x2
x3

我希望得到这样的文件

x1
x2
x3
...
a1
a2
a3

我使用Linux，因此tail -r对我不起作用。

Answer 1

这太丑了，我甚至羞于发帖...所以我想我会在一个更好的答案弹出后立即将其删除。

tac /path/to/file | awk '{ a[(NR-1)%3]=$0; if (NR%3==0) { print a[2] "\n" a[1] "\n" a[0] }}'

Answer 2

你可以使用关联数组在awk中完成所有这些：

BEGIN { j=1 }
++i>3 { i=1; ++j }
{ a[j,i]=$0 }
END{ for(m=j;m>0;--m)
       for(n=1;n<=3;++n) print a[m,n]
}

像这样运行：

awk -f script.awk file.txt

当然，如果你喜欢单行，你可以使用它：

awk 'BEGIN{j=1}++i>3{i=1;++j}{a[j,i]=$0}END{for(m=j;m>0;--m)for(n=1;n<=3;++n)print a[m,n]}' file.txt

解释

这使用两个计数器：i从1到3和j，它计算3行的组数。所有行都存储在关联数组a中，并在END块中反向打印。

测试

$ cat file
a1
a2
a3
b1
b2
b3
x1
x2
x3
$ awk 'BEGIN{j=1}++i>3{i=1;++j}{a[j,i]=$0}END{for(m=j;m>0;--m)for(n=1;n<=3;++n)print a[m,n]}' file
x1
x2
x3
b1
b2
b3
a1
a2
a3

Answer 3

使用文件：

~$ cat f
1
2
3
4
5
6
7
8
9

使用awk：将第一行存储在a中，然后将每行添加到a之上，并将第三行打印/重新初始化：

~$ awk '{a=$0"\n"a}NR%3==0{print a}NR%3==1{a=$0}' f
3
2
1
6
5
4
9
8
7

然后用tac再次反转：

~$ awk '{a=$0"\n"a}NR%3==0{print a}NR%3==1{a=$0}' f | tac
7
8
9
4
5
6
1
2
3

Answer 4

awk中的另一种方式

awk '{a[i]=a[i+=(NR%3==1)]?a[i]"\n"$0:$0}END{for(i=NR/3;i>0;i--)print a[i]}' file

输入

a1
a2
a3
x1
x2
x3
b1
b2
b3

输出

b1
b2
b3
x1
x2
x3
a1
a2
a3

Answer 5

这是一个纯粹的Bash（Bash≥4）可能性，对于不太大的文件应该没问题。 我们还假设文件中的行数是3的倍数。

mapfile -t ary < /path/to/file
for((i=3*(${#ary[@]}/3-1);i>=0;i-=3)); do
    printf '%s\n' "${ary[@]:i:3}"
done