Question

我有一个应用程序，需要在系统中安装FTDI D2XX Direct Drivers驱动程序。现在我使用Inno Setup创建安装脚本。如何获取有关FTDI驱动程序是否安装在系统（Windows）中的信息。是否有任何路径或注册表项可以检查以获得有关它的明确信息？

Answer 1

在发布这个答案时，我有两种方式想到，但我决定在那个时候展示我喜欢的那个。为了完整起见，我还包括检查系统中是否存在库的通用方法。

1。尝试调用FTDI驱动程序库函数

我认为你能做的最好的事情就是尝试使用延迟加载（delayload选项）从驱动程序库中调用一个函数。一个很好的呼叫功能是例如FT_GetLibraryVersion函数，您可以通过它获取库版本，并且不需要打开设备。在下面的示例中，代码显示了如何测试库是否存在于系统中：

[Code]
type
  ULONG = Cardinal;
  FT_STATUS = ULONG;

function FT_GetLibraryVersion(out lpdwVersion: DWORD): FT_STATUS;
  external 'FT_GetLibraryVersion@ftd2xx.dll stdcall delayload';

function IsFTD2xxInstalled: Boolean;
var
  Version: DWORD;
begin
  Result := True;
  try
    FT_GetLibraryVersion(Version);
  except
    Result := False;
  end;
end;

如果可以调用库函数，它只是一个探测器。因此没有结果也没有错误检查。

2。以通用方式检查库的存在

由于不推荐使用LoadDLL和FreeDLL等函数（并且没有检查库是否已加载的函数），因此检查系统中是否存在库的通用方法需要导入一些WinAPI函数。以下函数LibraryExists检查Inno Setup是否已加载给定名称的库，如果没有，则尝试加载和卸载它：

[Code]
#ifdef UNICODE
  #define AW "W"
#else
  #define AW "A"
#endif

const
  ERROR_MOD_NOT_FOUND = 126;

type
  HINSTANCE = THandle;
  HMODULE = HINSTANCE;

function LoadLibrary(lpLibFileName: string): HMODULE;
  external 'LoadLibrary{#AW}@kernel32.dll stdcall';
function FreeLibrary(hLibModule: HMODULE): BOOL;
  external 'FreeLibrary@kernel32.dll stdcall';
function GetModuleHandle(lpModuleName: string): HMODULE;
  external 'GetModuleHandle{#AW}@kernel32.dll stdcall';

procedure RaiseLastError(const Message: string; const Exclude: array of LongInt);
var
  I: Integer;
  LastError: LongInt;
begin
  LastError := DLLGetLastError;
  for I := 0 to GetArrayLength(Exclude) - 1 do
    if Exclude[I] = LastError then
      Exit;
  RaiseException(Format('%s' + #13#10 + '%d: %s', [Message, LastError,
    SysErrorMessage(LastError)]));
end;

function IsModuleLoaded(const Name: string): Boolean;
begin
  Result := GetModuleHandle(Name) <> 0;
  if not Result then
    RaiseLastError('GetModuleHandle call failed.', [ERROR_MOD_NOT_FOUND]);
end;

function LibraryExists(const Name: string): Boolean;
var
  Handle: HMODULE;
begin
  Result := IsModuleLoaded(Name);
  if not Result then
  begin
    Handle := LoadLibrary(Name);
    if Handle <> 0 then
    begin
      Result := True;
      FreeLibrary(Handle);
    end
    else
      RaiseLastError('LoadLibrary call failed.', [ERROR_MOD_NOT_FOUND]);
  end;
end;

您案件的可能用法：

function IsFTD2xxInstalled: Boolean;
begin
  Result := LibraryExists('ftd2xx.dll');
end;

如何检测系统中的FTDI驱动程序

1 个答案:

1。尝试调用FTDI驱动程序库函数

2。以通用方式检查库的存在