Question

Perl新手在这里。

我想循环一对单词，来自一个单词列表：

 @words = ("word1", "word2", "word3", "word4");

我想创建和处理所有单词对，但对排序并不重要，即对 ("word1", "word2")和("word2, "word1")被认为是相同的，只应生成其中一个。

有一种简单的方法吗？显而易见的解决方案是使嵌套循环有点像：

for my $i1 (0 ... $#words) {
    for my $i2 ($i1 + 1 ... $#words) {
        process_pair(words[$i1], words[$i2])
    }
}

但我正在寻找比这更像Perl-esque的东西。提前谢谢。

Answer 1

对于固定的R = 2，您提供的解决方案非常合适。

for my $i1 (0 ... $#words) {
   for my $i2 ($i1 + 1 ... $#words) {
      process_pair($words[$i1], $words[$i2])
   }
}

但是如果R更大或变量怎么办？你可以使用NestedLoops做一些强大的东西。

use Algorithm::Loops qw( NestedLoops );

my $R = 2;

NestedLoops(
   [  [ 0..$#words ],
      ( sub { [$_+1..$#words] } ) x ($R-1),
   ],
   \&process_pair,
);

或者作为迭代器

use Algorithm::Loops qw( NestedLoops );

my $R = 2;

my $iter = NestedLoops([
   [ 0..$#words ],
   ( sub { [$_+1..$#words] } ) x ($R-1),
]);

while (my @combo = $iter->()) {
    process_pair(@combo);
}

但这几乎不可读。专门解决这个问题的解决方案将是最清洁的。

use Math::Combinatorics qw( );

my $R = 2;

my $iter = Math::Combinatorics->new( count => $R, data => \@words );
while (my @combo = $iter->next_combination) {
    process_pair(@combo);
}

从perl中的列表生成无序对

1 个答案: