Question

我一直试图将允许我从ListPlot中提取点的东西放在一起，以便在进一步的计算中使用它们。我目前的方法是使用Locator []选择点。这适用于显示点，但我无法弄清楚如何从头部Dynamic []的构造中提取数值。以下是一个独立的示例。通过拖动灰色定位器，您应该能够选择点（由粉红色定位器指示并存储在q中，两个元素的列表）。这是情节下面的第二行。现在我想将q [[2]]传递给一个函数，或者只是简单地显示它。但是，Mathematica将q视为具有头Dynamic的单个实体，因此第二部分是不可能的（因此错误消息）。任何人都可以阐明如何将q转换为常规列表吗？

EuclideanDistanceMod[p1_List, p2_List, fac_: {1, 1}] /; 
   Length[p1] == Length[p2] := 
  Plus @@ (fac.MapThread[Abs[#1 - #2]^2 &, {p1, p2}]) // Sqrt;
test1 = {{1.`, 6.340196001221532`}, {1.`, 
    13.78779876355869`}, {1.045`, 6.2634018978377295`}, {1.045`, 
    13.754947081416544`}, {1.09`, 6.178367702583522`}, {1.09`, 
    13.72055251752498`}, {1.135`, 1.8183153704413153`}, {1.135`, 
    6.082497198000075`}, {1.135`, 13.684582525399742`}, {1.18`, 
    1.6809452373465104`}, {1.18`, 5.971583107298081`}, {1.18`, 
    13.646996905469383`}, {1.225`, 1.9480537697339537`}, {1.225`, 
    5.838386922625636`}, {1.225`, 13.607746407088161`}, {1.27`, 
    2.1183174369679234`}, {1.27`, 5.669799095595362`}, {1.27`, 
    13.566771130126131`}, {1.315`, 2.2572975468163463`}, {1.315`, 
    5.444014254828522`}, {1.315`, 13.523998701347882`}, {1.36`, 
    2.380307009155079`}, {1.36`, 5.153024664297602`}, {1.36`, 
    13.479342200528283`}, {1.405`, 2.4941312539733285`}, {1.405`, 
    4.861423833512566`}, {1.405`, 13.432697814928654`}, {1.45`, 
    2.6028066447609426`}, {1.45`, 4.619367407525507`}, {1.45`, 
    13.383942212133244`}};
DynamicModule[{p = {1.2, 10}, q = {1.3, 11}},
 q := Dynamic@
   First@test1[[
     Ordering[{#, EuclideanDistanceMod[p, #, {1, .1}]} & /@ test1, 
      1, #1[[2]] < #2[[2]] &]]];
 Grid[{{Show[{ListPlot[test1, Frame -> True, ImageSize -> 300], 
      Graphics@Locator[Dynamic[p]], 
      Graphics@
       Locator[q, Appearance -> {Small}, 
        Background -> Pink]}]}, {Dynamic@p}, {q},{q[[2]]}}]]

Answer 1

有几种方法可以从动态表达式中提取值。您可能想要的是Setting (documentation)，它会在评估Setting时将所有动态值解析为其值。

In[75]:= Slider[Dynamic[x]] (* evaluate then move the slider *)

In[76]:= FullForm[Dynamic[x]]
Out[76]//FullForm= Dynamic[x]

In[77]:= FullForm[Setting[Dynamic[x]]]
Out[77]//FullForm= 0.384`

这是一个稍微复杂的例子：

DynamicModule[{x},
  {Dynamic[x], Slider[Dynamic[x]], 
    Button["Set y to the current value of x", y = Setting[Dynamic[x]]]}
]

如果您评估上述表达式，请移动滑块然后单击按钮，滑块设置的当前值x将分配给y。如果您再次移动滑块，则y的值不会更改，直到您再次通过单击按钮进行更新。

您可以将值粘贴到笔记本中，调用函数，导出文件等，而不是分配给变量。

Answer 2

经过一番研究后，似乎答案围绕着Dynamic []是更新和显示表达式的包装这一事实。您想要动态更新的任何计算都必须放在包装器中：例如，不要像q = Dynamic[p] + 1那样使用Dynamic[q = p + 1; q]}]之类的内容。对于我的例子，我想将q分成两部分，这里是更新的代码：

DynamicModule[{p = {1.2, 10}, q = {1.3, 11}, qq, q1, q2}, 
 q := Dynamic[
   qq = First@
     test1[[Ordering[{#, EuclideanDistanceMod[p, #, {1, .1}]} & /@ 
         test1, 1, #1[[2]] < #2[[2]] &]]];
   {q1, q2} = qq;
   qq
   ];
 Grid[{{Show[{ListPlot[test1, Frame -> True, ImageSize -> 300], 
      Graphics@Locator[Dynamic[p]], 
      Graphics@
       Locator[q, Appearance -> {Small}, 
        Background -> Pink]}]}, {Dynamic@p}, {Dynamic@q}, {Dynamic@
     q1}}]]

如果我仍然缺少某些东西，或者有更清洁的方法，我欢迎任何建议......

将Dynamic []构造转换为数字列表

2 个答案: