Question

我想在设备管理器显示时检索串行com端口信息。例如，＆＃34;英特尔（R）主动管理技术 - SOL（COM3）＆＃34;。我知道使用命令＆＃34;模式＆＃34;检索串口列表，但没有像＆＃34;英特尔（R）主动管理技术 - SOL＆＃34;这样的描述。如何在Windows批处理文件中获取此信息？

Answer 1

更新回答

...由原始提问者在下面的评论中提供。显然Win32_SerialPort不包括USB-＆gt;串行设备。威廉的解决方案是改为查询Win32_PnPEntity。

就这样我仍觉得有用，这是一种刮掉该列表并将每一行设置为变量的方法：

@echo off
setlocal

:: wmic /format:list strips trailing spaces (at least for path win32_pnpentity)
for /f "tokens=1* delims==" %%I in ('wmic path win32_pnpentity get caption /format:list ^| find "COM"') do (
    call :setCOM "%%~J"
)

:: display all _COM* variables
set _COM

:: end main batch
goto :EOF

:setCOM <WMIC_output_line>
:: sets _COM#=line
setlocal
set "str=%~1"
set "num=%str:*(COM=%"
set "num=%num:)=%"
set str=%str:(COM=&rem.%
endlocal & set "_COM%num%=%str%"
goto :EOF

原始答案

将wmic与Win32_SerialPort一起使用，如下所示：

@echo off
setlocal

for /f "delims=" %%I in ('wmic path Win32_SerialPort get DeviceID^,Caption^,Description^,Name^,ProviderType /format:list ^| find "="') do (
    set "%%I"
)

echo %DeviceID%
echo %Caption%
echo %Description%
echo %Name%
echo %ProviderType%

请参阅Win32_SerialPort的文档，了解您可以查询的其他属性。我将把它作为练习让你找到一种独特设置变量的方法，这样你就不会在每个COM端口上用迭代覆盖它们。享受！

Answer 2

请使用mode命令获取可用COM端口的详细信息..

在Windows批处理中获取串行com端口描述

2 个答案:

更新回答

原始答案