邮件“无法继续”AppleScript功能

Question

我正在尝试编写AppleScript以与Mail（在Snow Leopard上）一起使用，以将邮件的图像附件保存到文件夹中。 AppleScript的主要部分是：

property ImageExtensionList : {"jpg", "jpeg"}
property PicturesFolder : path to pictures folder as text
property SaveFolderName : "Fetched"
property SaveFolder : PicturesFolder & SaveFolderName

tell application "Mail"
  set theMessages to the selection
  repeat with theMessage in theMessages
    repeat with theAttachment in every mail attachment of theMessage
      set attachmentFileName to theAttachment's name
      if isImageFileName(attachmentFileName) then
        set attachmentPathName to SaveFolder & attachmentFileName
        save theAttachment in getNonexistantFile(attachmentPathName)
      end if        
    end repeat
  end repeat
end tell

on isImageFileName(theFileName)
  set dot to offset of "." in theFileName
  if dot > 0 then
    set theExtension to text (dot + 1) thru -1 of theFileName
    return theExtension is in ImageExtensionList
  end if
  return false
end isImageFileName

运行时，我收到错误：

  

错误“邮件出错：无法继续isImageFileName。”数字-1708

其中错误-1708是：

  

事件并非由Apple事件处理程序处理。

但是，如果我将isImageFileName()复制/粘贴到另一个脚本中，如：

property ImageExtensionList : {"jpg", "jpeg"}

on isImageFileName(theFileName)
  set dot to offset of "." in theFileName
  if dot > 0 then
    set theExtension to text (dot + 1) thru -1 of theFileName
    return theExtension is in ImageExtensionList
  end if
  return false
end isImageFileName

if isImageFileName("foo.jpg") then
  return true
else
  return false
end if

它工作正常。 Mail为什么抱怨这个？

Answer 1

这可能是一个怪癖，但它有一个解释。如果您在tell application "whatever"块中，则所有调用都在该应用程序的字典的名称空间中进行，而不是在脚本的字典中进行。因此，您必须明确告诉AppleScript回顾您的脚本以获取名称。说my就像说tell me，指示脚本在哪里寻找功能。

Answer 2

尝试“my isImageFileName”。这不是Mail，只是AppleScript的一个怪癖。