Question

我使用下面的perl脚本将多个csv文件转换为excel电子表格，该脚本基本上是link中代码的修改版本，但我无法打开输出excel文件，它会弹出一条消息＆＃34;文件已损坏。＆＃34;

#!/usr/intel/bin/perl -W

use strict;
use Spreadsheet::WriteExcel::Big;
use Text::CSV_XS;

# Check for valid number of arguments
if (($#ARGV < 1) || ($#ARGV > 2)) {
   die("Usage: csv2xls csvfile_dir xlsfile\n");
};

my $csvdir  = $ARGV[0];
my $outfile = $ARGV[1];


# Create a new Excel workbook
my $workbook  = Spreadsheet::WriteExcel::Big->new($outfile);
my $csvfile   = "";
my $tab_title = "";

foreach $csvfile (glob("$csvdir/*.csv")) {
    print "$csvfile\n";
    # Open the Comma Separated Variable file
    open (CSVFILE, $csvfile) or die "$csvfile: $!";
    $csvfile =~ s/.*\///;
    $tab_title = (split(/\./,$csvfile))[0];
    print "-D- $tab_title\n";

    # Create a new Excel worksheet
    my $worksheet = $workbook->add_worksheet($tab_title);

    # Create a new CSV parsing object
    my $csv = Text::CSV_XS->new;

    # Row and column are zero indexed
    my $row = 0;

    while (<CSVFILE>) {
        if ($csv->parse($_)) {
            my @Fld = $csv->fields;
            print "-D- @Fld\n";
            my $col = 0;
            foreach my $token (@Fld) {
                $worksheet->write($row, $col, $token);
                $col++;
            }
            $row++;
        } else {
            my $err = $csv->error_input;
            print "Text::CSV_XS parse() failed on argument: ", $err, "\n";
        }
    }
}

我该如何解决？

Answer 1

您需要关闭工作簿。

$workbook->close();

同时将Excel模块升级到最新版本，我还遇到了类似的已损坏的Excel文件问题，这些问题在更新Spreadsheet::WriteExcel时已解决。

同样来自docs

请注意binmode（）的要求。包含Excel文件二进制数据。因此，如果您使用文件句柄，则应该在将它传递给new（）之前确保你binmode（）。你应该无论您是否在Windows平台上，都要执行此操作。这尤其适用于UTF-8所在系统上的perl 5.8用户可能在运行如RedHat Linux 9.如果你的程序，无论是有意还是无意，将UTF-8数据写入文件句柄传递给new（）会破坏创建的Excel文件。

将CSV转换为Excel会导致文件损坏

1 个答案: