Question

从集合1中删除集合2的匹配元素的n个实例的最佳方法是什么？

(let [coll-1 [8 2]
      coll-2 [8 8 8 2]

这是我第一次提出的解决原始问题的方法：

   ...
;; (remove (set coll-1) coll-2))
;;     --> ()

但意识到我必须实现：

   ...
;; (some-magic coll-1 coll-2))
;;     --> (8 8)

澄清：

 (some-magic {8 2} [8 8 8 2]) ;;Removes 1x8 and 1x2 from vector.
 (some-magic {8 8 2} [8 8 8 2]) ;;Removes 2x8 and 1x2 from vector.

修改

需要保留订单。

Answer 1

这是一个懒惰的解决方案，以distinct：

的风格编写

(defn some-magic [count-map coll]
  (let [step (fn step [xs count-map]
               (lazy-seq
                 ((fn [[f :as xs] count-map]
                    (when-let [s (seq xs)]
                      (if (pos? (get count-map f 0))
                        (recur (rest s) (update-in count-map [f] dec))
                        (cons f (step (rest s) count-map)))))
                   xs count-map)))]
    (step coll count-map)))

第一个参数需要是一个映射，指示要删除的每个值的数量：

(some-magic {8 1, 2 1} [8 8 8 2]) ;; Removes 1x8 and 1x2 
;=> (8 8)

(some-magic {8 2, 2 1} [8 8 8 2]) ;; Removes 2x8 and 1x2
;=> (8)

这是一个处理假值和无限输入的例子：

(take 10 (some-magic {3 4, 2 2, nil 1} (concat [3 nil 3 false nil 3 2] (range))))
;=> (false nil 0 1 4 5 6 7 8 9)

Answer 2

我没有看到任何内置的序列操作函数可以解决这个问题，尽管一个简单的循环可以很好地构建结果：

user> (loop [coll-1 (set coll-1) coll-2 coll-2 result []]
        (if-let [[f & r] coll-2]
          (if (coll-1 f)
            (recur (disj coll-1 f) r result)
            (recur coll-1 r (conj result f)))
          result))
[8 8]

从集合中删除匹配元素的n个实例

2 个答案: