我不熟悉汇编，并希望首先尝试直观地了解如何在不通过操作系统抽象（Linux或OSX）的情况下将字符串打印到终端上。
tl; dr 如何在OSX上使用NASM以最低级别（即没有系统调用）写入x86-64程序集中的stdout（打印到终端）？ BareMetal OS如何做到这一点？
大多数示例都显示this：
global start
section .text
start:
mov rax, 1
mov rdi, 1
mov rsi, message
mov rdx, 13
syscall
mov eax, 60
xor rdi, rdi
syscall
message:
db "Hello world", 10
在那里，他们使用syscall打印字符串，即relying on the operating system。我不是在寻找那个，而是为了如何在最低级别直接将字符串写入stdout。
我认为有这个exokernel项目BareMetal OS正在做这件事。虽然因为我刚刚参加集会，但我还不知道他们是如何实现这一目标的。从它看来，两个重要的文件是：
打印的相关代码似乎是这个（从这两个文件中提取）：
;
; Display text in terminal.
;
; IN: RSI = message location (zero-terminated string)
; OUT: All registers preserved
;
os_output:
push rcx
call os_string_length
call os_output_chars
pop rcx
ret
;
; Displays text.
;
; IN: RSI = message location (an ASCII string, not zero-terminated)
; RCX = number of chars to print
; OUT: All registers preserved
;
os_output_chars:
push rdi
push rsi
push rcx
push rax
cld ; Clear the direction flag.. we want to increment through the string
mov ah, 0x07 ; Store the attribute into AH so STOSW can be used later on
;
; Return length of a string.
;
; IN: RSI = string location
; OUT: RCX = length (not including the NULL terminator)
;
; All other registers preserved
;
os_string_length:
push rdi
push rax
xor ecx, ecx
xor eax, eax
mov rdi, rsi
not rcx
cld
repne scasb ; compare byte at RDI to value in AL
not rcx
dec rcx
pop rax
pop rdi
ret
但这对我来说并不完整（虽然我不知道，因为我是新人）。
所以我的问题是，按照BareMetal操作系统片段的说法，如何在OSX上使用NASM在x86-64程序集中写入stdout（打印到终端）？
答案 0 :(得分：8)
这是一个很好的练习。您将使用syscall（否则无法访问stdout），但您可以执行“裸机”写入，而无需任何外部库提供输出例程（如调用printf）。作为x86_64中对stdout的基本“裸机”写入的示例，我将一个示例放在一起，没有任何内部或系统函数调用：
section .data
string1 db 0xa, " Hello StackOverflow!!!", 0xa, 0xa, 0
section .text
global _start
_start:
; calculate the length of string
mov rdi, string1 ; string1 to destination index
xor rcx, rcx ; zero rcx
not rcx ; set rcx = -1
xor al,al ; zero the al register (initialize to NUL)
cld ; clear the direction flag
repnz scasb ; get the string length (dec rcx through NUL)
not rcx ; rev all bits of negative results in absolute value
dec rcx ; -1 to skip the null-terminator, rcx contains length
mov rdx, rcx ; put length in rdx
; write string to stdout
mov rsi, string1 ; string1 to source index
mov rax, 1 ; set write to command
mov rdi,rax ; set destination index to rax (stdout)
syscall ; call kernel
; exit
xor rdi,rdi ; zero rdi (rdi hold return value)
mov rax, 0x3c ; set syscall number to 60 (0x3c hex)
syscall ; call kernel
; Compile/Link
;
; nasm -f elf64 -o hello-stack_64.o hello-stack_64.asm
; ld -o hello-stack_64 hello-stack_64.o
<强>输出：
$ ./hello-stack_64
Hello StackOverflow!!!
对于一般用途，我将流程分为两部分（1）获取长度，（2）写入stdout。在strprn函数下面会将任何字符串写入stdout。它调用strsz来获取长度，同时保留堆栈上的目标索引。这减少了将字符串写入stdout的任务，并防止在代码中进行大量重复。
; szstr computes the lenght of a string.
; rdi - string address
; rdx - contains string length (returned)
section .text
strsz:
xor rcx, rcx ; zero rcx
not rcx ; set rcx = -1 (uses bitwise id: ~x = -x-1)
xor al,al ; zero the al register (initialize to NUL)
cld ; clear the direction flag
repnz scasb ; get the string length (dec rcx through NUL)
not rcx ; rev all bits of negative -> absolute value
dec rcx ; -1 to skip the null-term, rcx contains length
mov rdx, rcx ; size returned in rdx, ready to call write
ret
; strprn writes a string to the file descriptor.
; rdi - string address
; rdx - contains string length
section .text
strprn:
push rdi ; push string address onto stack
call strsz ; call strsz to get length
pop rsi ; pop string to rsi (source index)
mov rax, 0x1 ; put write/stdout number in rax (both 1)
mov rdi, rax ; set destination index to rax (stdout)
syscall ; call kernel
ret
进一步自动化常规输出到stdout NASM宏提供了一个方便的解决方案。示例strn（string_n的缩写）。它需要两个参数，字符串的地址和要写入的字符数：
%macro strn 2
mov rax, 1
mov rdi, 1
mov rsi, %1
mov rdx, %2
syscall
%endmacro
用于缩进，换行或编写完整的字符串。你可以通过传递3个参数来进一步概括，包括rdi的目的地。