Question

我的xml低于

<Report>
<rl>
    <id>12345;12346</id>
    <activity>a2/a3</activity>
    <result>r2/r3</result>
    <operator>test</operator>
    <timestamp>12/18/2014 3:51:19 PM</timestamp>
    <quantity>2</quantity>
</rl>
<rl>
    <id>22345;22346</id>
    <activity>a3/a4</activity>
    <result>r3/r4</result>
    <operator>test</operator>
    <timestamp>12/18/2014 3:51:19 PM</timestamp>
    <quantity>2</quantity>
</rl>
</Report>

和我的xsl，

<table border="1" style="border-width: 1px" width="90%" bordercolor="#C0C0C0" align="center">
    <tr>
        <th width="5%" align="center">
          <font color="#000000" face="Verdana" size="3">Index</font>
        </th>              
        <th width="15%" align="center">
          <font color="#000000" face="Verdana" size="3">ID A：</font>
        </th>
        <th width="15%" align="center">
          <font color="#000000" face="Verdana" size="3">ID B：</font>
        </th>
    </tr>
    <xsl:for-each select="Report/rl">
    <tr height="25">  
     <td width="5%" align="center" >
       <font color="#000000" face="Verdana" size="2">
         <xsl:value-of select="position()" />          
       </font>
     </td> 
     <td align="center">
       <font color="#000000" face="Verdana" size="2">
         <xsl:value-of select="idA" />
       </font>
     </td>
     <td align="center">
       <font color="#000000" face="Verdana" size="2">
         <xsl:value-of select="idB" />
       </font>
     </td>
    </tr>
  </xsl:for-each>
</table>

对于第一个rl，标签有12345：12346，我想将它们分成12345和12346并在'idA'和'idB'中显示它们。我该怎么办？

我的xslt版本是1.0。

Answer 1

假设总有两个值（以分号分隔），请使用：

<xsl:value-of select="substring-before(id, ';')"/>

填充idA单元格，并且：

<xsl:value-of select="substring-after(id, ';')"/>

填充idB单元格。

加了：

对于与发布相同的示例，您能详细说明吗？＆＃39;递归命名模板＆＃39;？

使用递归命名模板的解决方案如下所示：

XSLT 1.0

<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" omit-xml-declaration="yes" version="1.0" encoding="utf-8" indent="yes"/>

<xsl:template match="/Report">
    <table border="1">
        <tr>
            <th>Index</th>              
            <th>ID A</th>
            <th>ID B</th>
        </tr>
        <xsl:apply-templates select="rl"/>
    </table>
</xsl:template>

<xsl:template match="rl">
    <tr>
        <td>
            <xsl:value-of select="position()" />          
        </td>   
        <xsl:call-template name="tokenize">
            <xsl:with-param name="text" select="id"/>
        </xsl:call-template>
    </tr>
</xsl:template>

<xsl:template name="tokenize">
    <xsl:param name="text"/>
    <xsl:param name="delimiter" select="';'"/>
    <td>
        <xsl:value-of select="substring-before(concat($text, $delimiter), $delimiter)"/>
    </td>
    <xsl:if test="contains($text, $delimiter)">
        <!-- recursive call -->
        <xsl:call-template name="tokenize">
            <xsl:with-param name="text" select="substring-after($text, $delimiter)"/>
        </xsl:call-template>
    </xsl:if>
</xsl:template>

</xsl:stylesheet>

请注意，对于标题，我们假设事先知道列数。否则，您必须使用类似的递归模板来生成标题单元格。

Answer 2

检查此示例

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:msxsl="urn:schemas-microsoft-com:xslt" exclude-result-prefixes="msxsl"
>
    <xsl:output method="xml" indent="yes"/>

    <xsl:template match="*">
          <xsl:for-each select="rl">
            <node>
            <idA>
                <xsl:value-of select="substring-before(id,';')"/>
            </idA>
            <idB>
              <xsl:value-of select="substring-after(id,';')"/>
            </idB>
            </node>
          </xsl:for-each>
    </xsl:template>

</xsl:stylesheet>

在foreach中拆分标签

2 个答案:

加了：