Question

我有以下代码。我在MS Access 2010中使用表单在我的表Nlog中输入新行。当我尝试运行代码时，它给出了错误运行时错误'3061'：参数太少。预期1.

我找不到错误！

Private Sub Command128_Click()
    'add data to table
    CurrentDb.Execute "INSERT INTO NLog(IDKEY, Company, CoName, State, City, AmtpdTotal, DateRec, Notified, DateNotice, AcctID, TaxType, Period, NoticeReason, Resolution, TaxDue, Intdue, PenDue, Dateres, Amtpdint, amtpdpen, amtpdtax, Assigned, subAssgn, Resolved) " & _
        " VALUES(" & Me.TxtIDKEY & ",'" & Me.Company & "','" & Me.CoName & "','" & _
        Me.State & "','" & Me.City & "','" & Me.TxtAmtpdTotal & "','" & _
        Me.DateRec & "','" & Me.Notified & "','" & _
        Me.DateNotice & "','" & Me.AcctID & "','" & Me.TaxType & "','" & Me.Period & "','" & _
        Me.NoticeReason & "','" & Me.Resolution & "','" & Me.TaxDue & "','" & Me.IntDue & "','" & Me.PenDue & "','" & _
        Me.DateRes & "','" & Me.AmtPdInt & "','" & Me.AmtpdPen & "','" & Me.AmtpdTax & "','" & _
        Me.Assigned & "','" & Me.txtsubass & "','" & Me.Resolved & "')", dbFailOnError 
MsgBox ("Entry Added")

Answer 1

使用字符串变量来保存INSERT语句。这允许您Debug.Print字符串，以便您可以检查代码创建的实际语句。你可以Execute字符串。

Dim strInsert As String
strInsert = "INSERT INTO NLog(IDKEY, Company, CoName, State, City, AmtpdTotal, DateRec, Notified, DateNotice, AcctID, TaxType, Period, NoticeReason, Resolution, TaxDue, Intdue, PenDue, Dateres, Amtpdint, amtpdpen, amtpdtax, Assigned, subAssgn, Resolved) " & _
    " VALUES(" & Me.TxtIDKEY & ",'" & Me.Company & "','" & Me.CoName & "','" & _
    Me.State & "','" & Me.City & "','" & Me.TxtAmtpdTotal & "','" & _
    Me.DateRec & "','" & Me.Notified & "','" & _
    Me.DateNotice & "','" & Me.AcctID & "','" & Me.TaxType & "','" & Me.Period & "','" & _
    Me.NoticeReason & "','" & Me.Resolution & "','" & Me.TaxDue & "','" & Me.IntDue & "','" & Me.PenDue & "','" & _
    Me.DateRes & "','" & Me.AmtPdInt & "','" & Me.AmtpdPen & "','" & Me.AmtpdTax & "','" & _
    Me.Assigned & "','" & Me.txtsubass & "','" & Me.Resolved & "')"
Debug.Print strInsert
CurrentDb.Execute strInsert, dbFailOnError

然后，您可以在立即窗口中查看已完成的语句（来自Debug.Print的输出）。 Ctrl + g 将带您进入立即窗口。

如果错误不明显，您可以复制语句文本，在查询设计器中创建新查询，将其切换到SQL视图，然后粘贴到复制的语句中。当您尝试从设计器运行该查询时，Access将显示一个参数对话框，要求您提供参数的值。请注意，对话框还包含参数的“名称”。此问题的原因通常是拼写错误的字段名称 - 由于Access无法按该名称查找字段，因此它假定它必须是参数。

或者，您可以使用VBA代码向您显示查询中任何参数的名称：

Dim db As DAO.Database
Dim qdf As DAO.QueryDef
Dim prm As DAO.Parameter
Set db = CurrentDb
Set qdf = db.CreateQueryDef(vbNullString, strInsert)
For Each prm In qdf.Parameters
    Debug.Print prm.Name
Next

使用“插入”命令运行时错误3061 VBA

1 个答案: