Question

我有关于XSLT转换的以下问题 - 我需要转换XML文件，考虑所有父节点中的属性值到根。所以有这样的代码（将XY属性视为带有“X，Y”值的字符串）：

<Layout XY="40,20">
   <Layout XY="0,20">
     <Circle OffsetX="0"/>
    </Layout>
   <Circle OffsetX="6" />
   <Layout XY="100,20">
    <Circle OffsetX="0"/>
    <Layout XY="200,20">
      <Circle OffsetX="5"/>
    </Layout>
   </Layout>
</Layout>

我需要输出

<Layout XY="40,20">
   <Layout XY="0,20">
     <Circle OffsetX="40"/>
    </Layout>
   <Circle OffsetX="46" />
   <Layout XY="100,20">
    <Circle OffsetX="140"/>
    <Layout XY="200,20">
      <Circle OffsetX="345"/>
    </Layout>
   </Layout>
</Layout>

我试图使用这样的模板来使用XSLT转换：

<!-- Copy template -->

<xsl:template match="@*|node()">
   <xsl:copy>
      <xsl:apply-templates select="@*|node()"/>
   </xsl:copy>
</xsl:template>

<!-- Change values -->

<xsl:template match="Circle/@OffsetX">   
  <xsl:param name="newOffsetX" select="substring-before(../../@XY,',')"/>
    <xsl:apply-templates select="@*|node()"/>       
    <xsl:attribute name="OffsetX">
      <xsl:value-of select=".+$newOffsetX"/>
    </xsl:attribute>               
</xsl:template>

但这只是一个级别的解决方案。是否有可能只使用XSLT进行这样的转换？

Answer 1

如果您正在使用XSLT 1.0，则需要一个递归遍历节点树的模板：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" indent="yes" omit-xml-declaration="yes"/>

  <xsl:template match="@*|node()">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="@XY" mode="sumXOffset" name="SumXOffset">
    <xsl:param name="currentValue"
               select="substring-before(., ',')" />

    <xsl:variable name="sum">
      <xsl:apply-templates select="(../ancestor::*/@XY)[last()]" mode="sumXOffset" />
    </xsl:variable>

    <xsl:value-of select="$currentValue + 
                          concat('0', $sum)" />
  </xsl:template>

  <xsl:template match="@OffsetX">
    <xsl:attribute name="{name()}">
      <xsl:call-template name="SumXOffset">
        <xsl:with-param name="currentValue" select="." />
      </xsl:call-template>
    </xsl:attribute>
  </xsl:template>
</xsl:stylesheet>

在样本XML上运行时，结果为：

<Layout XY="40,20">
  <Layout XY="0,20">
    <Circle OffsetX="40" />
  </Layout>
  <Circle OffsetX="46" />
  <Layout XY="100,20">
    <Circle OffsetX="140" />
    <Layout XY="200,20">
      <Circle OffsetX="345" />
    </Layout>
  </Layout>
</Layout>

如果您有可用的XSLT 2.0处理器，解决方案要简单得多：

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" indent="yes" omit-xml-declaration="yes"/>

  <xsl:template match="@*|node()">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="@OffsetX">
    <xsl:attribute name="{name()}">
      <xsl:value-of select=". + sum(ancestor::*/@XY/substring-before(','))"/>
    </xsl:attribute>
  </xsl:template>
</xsl:stylesheet>

Answer 2

我会这样做：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:exsl="http://exslt.org/common"
extension-element-prefixes="exsl">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="Circle/@OffsetX">  
    <xsl:variable name="previous-X">
        <xsl:for-each select="ancestor::*[@XY]">
            <x><xsl:value-of select="substring-before(@XY, ',')"/></x>
        </xsl:for-each>
    </xsl:variable>
    <xsl:attribute name="OffsetX">
        <xsl:value-of select=". + sum(exsl:node-set($previous-X)/x)"/>
    </xsl:attribute>               
</xsl:template>

</xsl:stylesheet>

Answer 3

有一种方法可以在没有递归模板的情况下在XSLT 1.0中实现这一点（并不是说有任何问题！），那就是将运行总计从模板传递给模板作为参数。实质上，也可以在身份模板中使用newOffsetX参数。

试试这个XSLT

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:template match="@*|node()">
        <xsl:param name="newOffsetX" select="0" />
        <xsl:copy>
            <xsl:apply-templates select="@*|node()">
                <xsl:with-param name="newOffsetX" select="$newOffsetX + number(substring-before(concat('0', @XY, ','), ','))" />
            </xsl:apply-templates>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="@OffsetX">
        <xsl:param name="newOffsetX" select="0" />
        <xsl:attribute name="OffsetX">
            <xsl:value-of select="$newOffsetX + number(.)" />
        </xsl:attribute>
    </xsl:template>
</xsl:stylesheet>

有趣的表达式substring-before(concat('0', @XY, ','), ',')用于处理没有@XY属性的节点。当存在@XY属性，例如值为“40,20”时，'concat'返回“040,20”，因此X数在数值上仍然相同。当@XY不存在时，concat会返回0,，因此X编号为“0”。

XSLT转换为属性

3 个答案: