Question

我不确定excel是否可以这样做，但我正在尝试简化从twitter获得的数据转储。

基本上我想做的是：

如果推文（在A栏中）含有苹果或橙色OR梨，那么它可以被分类（在B栏中）为“水果”但是如果它有胡萝卜或南瓜或生菜它将被归类为“蔬菜”。如果没有这些，则可归类为“无”

这可能吗？

提前致谢。

Answer 1

这里使用数组常量和范围。

=IF(SUMPRODUCT(IF(ISERROR(SEARCH({"apple","orange","pear"},A1)),0,1))>0,"Fruit",IF(SUMPRODUCT(IF(ISERROR(SEARCH({"carrot","squash","lettuce"},A1)),0,1))>0,"Vegetable","None"))

现在，例如，水果和蔬菜都存在于一个字符串中，它将始终首先测试水果，因为这是配方的排列方式。（例如＆＃34;沙拉上的苹果多于生菜和＃34;将返回＆＃34; Fruit＆＃34;）。
您还可以使用包含列表而不是数组常量的范围例如，您可以将水果列表放在C列（C1：C3）中，将蔬菜列表放在D列（D1：D3）中。
您的公式将是：

=IF(SUMPRODUCT(IF(ISERROR(SEARCH(C$1:C$3,A1)),0,1))>0,"Fruit",IF(SUMPRODUCT(IF(ISERROR(SEARCH(D$1:D$3,A1)),0,1))>0,"Vegetable","None"))

但您需要使用 Ctrl + Shift + Enter 将其作为数组公式输入。
当水果和蔬菜出现在字符串上时，同样的结果和规则也适用。 HTH。

Answer 2

不确定

试试这个公式

=IF(
    OR(
       NOT(ISERROR(SEARCH("apple",A1))),
       NOT(ISERROR(SEARCH("pear",A1))),
       NOT(ISERROR(SEARCH("orange",A1)))
    ),
    "fruit",
    IF(
       OR(
          NOT(ISERROR(SEARCH("carrot",A1))),
          NOT(ISERROR(SEARCH("squash",A1))),
          NOT(ISERROR(SEARCH("lettuce",A1)))
      ),
      "veggie",
      "none"
  )
)

按关键字对单元格进行分类

2 个答案: