Question

我的应用程序突然停止编译并显示一堆错误，例如＆＃34;找不到与给定名称匹配的资源：attr android：actionModeShareDrawable＆＃34;。

我没有使用appcompat 21.0.0或者android 5 sdk，因为StackOverflow建议的答案很多，并且上周五已经编译了相同的代码。

唯一不同的是，现在我使用的是Android Studio RC2。

这是我的build.gradle：

buildscript {
    repositories {
        maven { url 'https://maven.fabric.io/repo' }
    }

    dependencies {
        classpath 'io.fabric.tools:gradle:1.+'
    }
}
apply plugin: 'com.android.application'
apply plugin: 'io.fabric'

repositories {
    maven { url 'https://maven.fabric.io/repo' }
}


android {
    compileSdkVersion Integer.parseInt(project.ANDROID_BUILD_SDK_VERSION)
    buildToolsVersion project.ANDROID_BUILD_TOOLS_VERSION


    defaultConfig {
        //noinspection GroovyAssignabilityCheck
        minSdkVersion Integer.parseInt(project.ANDROID_BUILD_MIN_SDK_VERSION)
        targetSdkVersion Integer.parseInt(project.ANDROID_BUILD_TARGET_SDK_VERSION)
        versionCode 15
        versionName "1.8"
    }


    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.txt'
            signingConfig signingConfigs.release
        }

        debug {
            debuggable true
            applicationIdSuffix ".debug"
        }
    }
}

dependencies {
    compile 'com.android.support:support-v4:19.1.0'
    compile 'com.android.support:appcompat-v7:20.0.0'
    compile fileTree(dir: 'libs', include: ['*.jar'])
    compile 'com.sothree.slidinguppanel:library:+'
    provided 'com.google.android.gms:play-services:5.0.89'
    compile project(':libraries:ViewPagerIndicator')
    compile files('libs/mobileservices-1.1.5.jar')
    compile files('libs/volley.jar')
    compile files('libs/picasso-2.3.5-SNAPSHOT.jar')
    compile 'com.microsoft.azure.android:azure-storage-android:0.3.1'
    compile 'com.squareup.okhttp:okhttp:2.1.0'
    compile 'com.squareup.okhttp:okhttp-urlconnection:2.1.0'
    compile('com.crashlytics.sdk.android:crashlytics:2.1.0@aar') {
        transitive = true;
    }
}

这是gradle.properties：

ANDROID_BUILD_MIN_SDK_VERSION=15
ANDROID_BUILD_TARGET_SDK_VERSION=19
ANDROID_BUILD_TOOLS_VERSION=20
ANDROID_BUILD_SDK_VERSION=19

我没有引用Android 5 SDK或兼容性库v21，那么为什么要困扰我这个资源键呢？

Answer 1

我不知道是什么导致它，但我有同样的问题，这个解决方法对我有用：

添加

configurations.all {
    resolutionStrategy {
        force 'com.android.support:appcompat-v7:20.0.0'
    }
}

在gradle文件中的android {}块下面。

编辑：此错误是由AndroidSlidingUpPanel库引起的。修复是在项目中包含该库，如下所示：

compile('com.sothree.slidinguppanel:library:+') {
    exclude group: 'com.android.support', module: 'appcompat-v7'
}

找不到与给定名称匹配的资源：attr android：actionModeShareDrawable即使我使用的是appcompat 20

1 个答案: