Question

我有一段代码：

links
    |> Seq.map (fun x -> x.GetAttributeValue ("href", "no url"))

我想改写为：

links
    |> Seq.map (fun x -> (x.GetAttributeValue "href" "no url"))

但是F＃编译器似乎并不喜欢这样。我的印象是这两个函数调用是可以互换的：

f (a, b)
(f a b)

我得到的错误是：

无法从此代码位置访问带有2个参数的成员或对象构造函数“GetAttributeValue”。方法'GetAttributeValue'的所有可访问版本都有2个参数。

这似乎很有趣，因为它似乎表明它需要我所提供的东西。我在这里缺少什么？

Answer 1

F＃中的常规函数调用没有括号，参数用空格分隔。定义几个参数的函数的简单方法是写这个：

let add a b = a + b

正如Pascal所说，这种指定参数的方式称为currying - 这个想法是函数只接受一个参数，结果是一个接受第二个参数并返回实际结果（或另一个函数）的函数。当调用像这样的简单函数时，你会写add 10 5，编译器（原则上）将其解释为((add 10) 5)。这有一些很好的优点 - 例如，它允许您使用部分函数应用程序，其中您只指定函数的前几个参数：

let addTen = add 10 // declares function that adds 10 to any argument
addTen 5  // returns 15
addTen 9  // returns 19

此功能在处理列表时非常有用：

// The code using explicit lambda functions..
[ 1 .. 10 ] |> List.map (fun x -> add 10 x) 

// Can be rewritten using partial function application:
[ 1 .. 10 ] |> List.map (add 10)

现在，让我们进入令人困惑的部分 - 在F＃中，您还可以使用元组，元组是简单的数据类型，允许您将多个值组合成单个值（请注意，元组与任何函数无关）办法）。你可以写一下：

let tup = (10, "ten")    // creating a tuple
let (n, s) = tup         // extracting elements of a tuple using pattern 
printfn "n=%d s=%s" n s  // prints "n=10 s=ten"

当你编写一个函数，它用逗号分隔括号中的参数时，你实际上是在编写一个函数，它接受一个单元参数，这是一个元组：

// The following function:
let add (a, b) = a * b

// ...means exactly the same thing as:
let add tup = 
  let (a, b) = tup  // extract elements of a tuple
  a * b

// You can call the function by creating tuple inline:
add (10, 5)
// .. or by creating tuple in advance
let t = (10, 5)
add t

这是一个不同类型的函数 - 它需要一个参数，它是一个元组，而第一个版本是一个带有两个参数的函数（使用currying）。

在F＃中，情况有点复杂 - .NET方法显示为将元组作为参数的方法（因此您可以使用带括号的符号来调用它们），但它们有些限制（例如，您不能首先创建一个元组，然后调用方法，只给它一个元组）。此外，编译的F＃代码实际上并不以curry形式生成方法（因此您不能直接从C＃使用部分函数应用程序）。这是由于性能原因 - 大多数情况下，您指定所有参数，这可以更有效地实现。

但是，原则是函数要么采用多个参数，要么将元组作为参数。

Answer 2

在f (a,b)中，f必须是一个带有单个参数的函数（这是一对）。

在f a b (f a) b的缩写，f应用于a时会返回应用于b的函数。

两者几乎都是将参数传递给函数的等效方法，但是你不能使用为另一种风格设计的函数。第二种风格称为“currying”。它的优点是只要通过a就允许进行一些计算，特别是如果您要使用具有不同a的相同b。在这种情况下，您可以写：

let f_a = f a (* computations happen now that a is available *)
in
f_a b1 .... f_a b2 ....

Answer 3

要回答你的隐含问题，在这种情况下，编写一个小辅助函数会很有用：

let getAttrVal (x:TypeOfX) key default = x.GetAttributeValue(key, default)

//usage
links |> Seq.map (fun x -> getAttrVal x "href", "no url"))

并且根据您的使用方式，将它向后调整可能更有用：

let getAttrVal key default (x:TypeOfX) = x.GetAttributeValue(key, default)

//partial application
let getHRef = getAttrVal "href" "no url"

//usage
links |> Seq.map (fun x -> getHRef x)

//or, same thing:
links |> Seq.map getHRef

F＃函数调用语法混乱

3 个答案: