Question

我使用此代码查看我的网页....它是使用air 3.2 for desktop ...如何使用air 3.2 for android？ ....它没有加载任何东西，只有白色屏幕！

package {
import flash.display.Sprite;
import flash.html.HTMLLoader;
import flash.net.URLRequest;

public class HTMLLoaderExample extends Sprite
{
    public function HTMLLoaderExample()
    {
        var html:HTMLLoader = new HTMLLoader();
        var urlReq:URLRequest = new URLRequest("http://www.doomanco.com/");
        html.width = stage.stageWidth;
        html.height = stage.stageHeight;
        html.load(urlReq); 
        addChild(html);
        html.x = 0;
        html.y = 0;
        }
    }
 }

Answer 1

正如Adobe所说的那样HTMLLoader：“AIR配置文件支持：所有桌面操作系统都支持此功能，但移动设备或AIR for TV设备不支持此功能。您可以测试支持在运行时使用HTMLLoader.isSupported属性。有关跨多个配置文件的API支持的详细信息，请参阅AIR配置文件支持。“，我认为您的Android设备不支持，您可以验证使用HTMLLoader.isSupported属性。有关详细信息，请参阅此处：Adobe.com : HTMLLoader和此处：Adobe.com : Device profiles for AIR。

Answer 2

谢谢老兄@DodgerThud＆amp; @akmozo .....完成了这个：

package  {
import flash.display.MovieClip;
import flash.media.StageWebView;
import flash.geom.Rectangle;
import flash.events.KeyboardEvent;
import flash.ui.Keyboard;
import flash.desktop.NativeApplication;
import flash.display.Stage; 
import flash.display.StageAlign; 
import flash.display.StageScaleMode; 
import flash.events.Event; 

public class StageWebViewExample extends MovieClip{

    private var webView:StageWebView = new StageWebView();

    public function StageWebViewExample() 
    {

        stage.scaleMode = StageScaleMode.NO_SCALE;
        stage.align = StageAlign.TOP_LEFT;

        webView.stage = this.stage;
        webView.viewPort = new Rectangle( 0, 0, stage.fullScreenWidth, stage.fullScreenHeight );
        webView.loadURL( "http://www.google.com" );

        stage.addEventListener( KeyboardEvent.KEY_DOWN, onKey );
    }

    private function onKey( event:KeyboardEvent ):void
    {
        if( event.keyCode == Keyboard.BACK && webView.isHistoryBackEnabled )
        {
            trace("Back.");
            webView.historyBack();
            event.preventDefault();
        }

        if( event.keyCode == Keyboard.SEARCH && webView.isHistoryForwardEnabled )
        {
            trace("Forward.");
            webView.historyForward();
        }
    }
   }
 }

如何使用air 3.2和HTMLLoader？

2 个答案: