Question

我必须为我的学校项目处理工作。所以我在一个数组中加载图片，然后在一个新类中我有另一个数组，每次创建该类时我都会将图片放入该数组中。每次我创建该类时，我都会将图像放在不同的位置并且工作正常但是一旦我尝试调整这些图像的比例，它就会调整其他类中图像的比例。我假设它改变了所有这些图像的比例，因为它改变了我的第一个数组中图像的比例，我没有创建一个新图像。有办法解决这个问题吗？这是我的代码。这是我加载图片的地方：

class ItemLoader
{
  PImage[] itemArray;
  ArrayList itemCollection; 
  String itemType;
  int amountOfFrames;
  int amountOfItems = 1;

  ItemLoader()
  {
    itemCollection = new ArrayList();
    LoadImage();
  }

  void LoadImage()
  {
    for(int ii = 0; ii < amountOfItems; ii++)
    {
     AssignItemType(ii);
     itemArray = new PImage[amountOfFrames];

      for(int i = 0; i < amountOfFrames; i ++)
      {
        String filenaam = itemType + nf(i, 5) + ".png";
        itemArray[i] = loadImage(filenaam);
      }
    itemCollection.add(itemArray);
    }
  }

  void AssignItemType(int itemNumber)
  {
    switch(itemNumber)
    {
      case 0: itemType = "Leaves"; amountOfFrames = 21;
      break;

      case 1: itemType = "Apple";
      break;

      case 2: itemType = "Bannana";
      break;

      case 3: itemType = "Pear";
      break;

      case 4: itemType = "Cherry";
      break;

      case 5: itemType = "Owl";
      break;

      case 6: itemType = "Bird";
      break;
    }
  }
}

然后这是我创建类的实例时：

itemList.add(new ItemSpawn(randomX,randomY,0, strokeThickness,itemLoader.itemCollection));

这是我通过数组循环来为图像设置动画的地方：

class ItemSpawn
{
  PImage[] animationFrames;
  PImage lastFrame;
  float frameCounter;

  int x_loc;
  int y_loc;
  float ImageScale = 0;
  int ImageRotation = 0;  

 ItemSpawn(int x_loc_par, int y_loc_par, int _itemType, float _strokeSize, ArrayList _tempArray)
 {
  animationFrames = (PImage[]) _tempArray.get(_itemType);
  x_loc = x_loc_par;
  y_loc = y_loc_par;
  ApplyScaleRotation();
 }

  void ApplyScaleRotation()
  {
    ImageScale = 0.5;
    ImageRotation = int(random(0,360));

    for(int i = 0; i < animationFrames.length; i++)
    {
      animationFrames[i].resize(int(animationFrames[i].width * ImageScale), int(animationFrames[i].height * ImageScale));
    }    
  }

  void LoopAnimation()
  {
  int convertCount = int(round(frameCounter));

    if(convertCount < animationFrames.length - 1)
    {
     image(animationFrames[convertCount],x_loc - (animationFrames[convertCount].width/2) ,y_loc - (animationFrames[convertCount].height/2));
     frameCounter += 0.4;

    }else
    {
      image(animationFrames[animationFrames.length - 1],x_loc - (animationFrames[convertCount].width/2),y_loc - (animationFrames[convertCount].height/2));
    }
  }
}

Answer 1

在您的代码中，ItemSpawn类的每个对象都使用相同的 PImage[]数组。当您在ItemSpawn实例之一中更改图像时 - 所有其他实例都会看到此更改。

每个ItemSpawn对象都有图像的私有副本 - 然后它可以安全地修改图像。

考虑这样简化的课程：

class X {
    int[] array;

    X(int[] array) {
        this.array = array;
    }
    void modify() {
        array[0] = 99;
    }
}

我们可以使用相同的数组创建此类的2个不同的对象（x1和x2）：

int[] values = {1,2,3,4};
X x1 = new X(values);
X x2 = new X(values);

接下来x1修改数组：

x1.modify();

println(x1.array[0]);   // output: 99
println(x2.array[0]);   // output: 99

解决方案是为PImage[]类的每个对象创建ItemSpawn数组的深层副本：

ItemSpawn(int x_loc_par, int y_loc_par, int _itemType, float _strokeSize, ArrayList _tempArray)
{

  // old:
  // animationFrames = (PImage[]) _tempArray.get(_itemType);

  // new:
  PImage[] images = _tempArray.get(_itemType);
  animationFrames = new PImage[images.length];  // create new array with the same length

  // copy all images
  for (int i = 0; i < images.length; i++) {
      PImage img = images[i];
      animationFrames[i] = img.get();  // returns copy of this image
  }
  ...
}

操纵我的图像的比例

1 个答案: