Question

有没有办法直接将FDQuery结果复制到记录数组？所以这是声明的类型：

type
  TPerson = record
    id: integer;
    name: string;
    surname: string;
  end;

type
  TPersonList = array of TPerson;

我的SQLite数据库包含id, name列和surname列。通常我应该像这样向该数组添加值：

var Persons: TPersonList;
begin
Persons[0].id := FDQuery1.FieldByName('id').AsInteger;
....
....
....
end;

但有没有更好/更紧凑的方法呢？一些功能如：

while not FDQuery.eof do begin
    ...
    Persons[i] := FDQuery1[i];
    ...
end;

也许直接或在循环中？或者我应该创建一些功能来做到这一点？因为我有很多列，并且有许多不同的记录类型，它们具有不同的结构，但具有类似于db。

的精确结构

Answer 1

没有简单的方法直接执行此操作，但您可以使用一些技术来提高源和运行时性能的效率。一种方法可能是创建一个简单的帮助器来从给定的数据集初始化适当类型的新值。

你可以使用一个记录方法，但这会使缓存的字段引用不那么优雅，所以我建议一个单独的专用初始化类。这可以使用缓存的字段引用来提高效率：

type
  TPersonFDInitialiser = class
  private
    fldID: TIntegerField;
    fldName: TStringField;
    fldSurname: TStringField;
    function get_NewValue: TPerson;
  public
    constructor Create(const aSource: TDataset);
    property NewValue: TPerson read get_NewValue;
  end;

在构造函数中缓存字段引用可避免每次检索每条记录的值时都必须按名称查找它们。对字段数据类型使用适当的类允许直接访问每个字段值而无需任何转换：

constructor TPersonFDInitialiser.Create(const aSource: TDataset);
begin
  inherited;

  fldID      := aSource.FieldByName('id') as TIntegerField;
  fldName    := aSource.FieldByName('name') as TStringField;
  fldSurname := aSource.FieldByName('surname') as TStringField;
end;


function TPersonFDInitialiser.get_NewValue: TPerson;
begin
  result.ID      := fldID.Value;
  result.Name    := fldName.Value;
  result.Surname := fldSurname.Value;
end;

正如您所看到的，这不是大量的工作（比显式初始化1个记录值所需要的多一点）但是使迭代使用更优雅，更快速地编写，看起来像这样：

recno := 0;
init := TPersonFDInitialiser.Create(qryPersons);
try
  while NOT qryPersons.EOF do
  begin
    persons[recno] := init.NewValue;

    qryPersons.Next;
    Inc(recno);
  end;

finally
  init.Free;
end;

哪些qryPersons是某些 TFDQuery ，它返回人行，而persons是 TPerson 记录的数组（当然，大小/ dminesioned是适当的））

通过使用 TDataset 基类（ TFDQuery 最终派生出来），您可以在初始化 TPerson 来自 TDataset 后代，无论是 TFDQuery 还是 TClientDataset 等等（只要该数据集中的字段一致命名，如果需要的话，可以在这方面使初始化者更加灵活。这只是一个练习。

进一步

根据您的需要，可以通过许多增强功能来提高此类初始化类的效用，例如：

// To initialise a one-off, new TPerson value from a data set use a // class function which will internally create an initialiser, obtain // a new TPerson then destroy the initialiser for you: // // Note that this will need to be overloaded if it has the same name as // the instance method (which must also then be overloaded): class function TPersonFDInitialiser.NewValue(const aSource: TDataset): TPerson; overload; // Implement a procedure which will initialise an existing TPerson value // (by reference) with values from the current record. // // Again, a class procedure overload could be provided for one-off use // taking care of creating and freeing the required initialiser: class procedure TPersonFDInitialiser.SetPerson(const aSource: TDataset; var aPerson: TPerson); overload; procedure TPersonFDInitialiser.SetPerson(var aPerson: TPerson); overload;

注意：这些SetPerson方法可以通过 get_NewValue 实际调用该方法的方式实现，这样您在整个实现中只有一个方法这实际上是任何值的设置。这将消除初始化代码的重复，提高初始化类的可靠性和可维护性：

function TPersonFDInitialiser.get_NewValue: TPerson; begin SetPerson(result); end; procedure TPersonFDInitialiser.SetPerson(var aPerson: TPerson); begin aPerson.ID := fldID.Value; aPerson.Name := fldName.Value; aPerson.Surname := fldSurname.Value; end;

FDQuery（SQL）导致Delphi中的记录数组

1 个答案: