Question

我想了解有关定义依赖于外部状态的插件任务的最佳实践的反馈（即在引用该插件的build.gradle中定义）。我使用扩展程序对象和闭包来推迟访问这些设置，直到它们需要并且可用。我也对在任务之间共享状态感兴趣，例如将一个任务的输出配置为另一个任务的输入。

代码使用＆＃34; project.afterEvaluate＆＃34;通过扩展对象配置所需设置时定义任务。这似乎比应该更复杂。如果我将代码移出＆＃34; afterEvaluate＆＃34;，它将获得compileFlag == null，这不是外部设置。如果再次更改代码以使用＆lt;＆lt;或者doLast语法，然后它将获得外部标志......但是它无法使用类型：Exec和其他类似的有用类型。

我觉得我在某些方面与格拉德作战，这意味着我不能更好地理解如何与之合作。以下是我所使用的简化伪代码。这有效，但我想看看这是否可以简化，或者确实是最佳做法。此外，除非正在执行任务，否则不应抛出异常。

apply plugin: MyPlugin

class MyPluginExtension {
    String compileFlag = null
}

class MyPlugin implements Plugin<Project> {

    void apply(Project project) {

        project.extensions.create("myPluginConfig", MyPluginExtension)

        project.afterEvaluate {

            // Closure delays getting and checking flag until strictly needed
            def compileFlag = {
                if (project.myPluginConfig.compileFlag == null) {
                    throw new InvalidUserDataException(
                            "Must set compileFlag:  myPluginConfig { compileFlag = '-flag' }")
                }
                return project.myPluginConfig.compileFlag
            }

            // Inputs for translateTask
            def javaInputs = {
                project.files(project.fileTree(
                        dir: project.projectDir, includes: ['**/*.java']))
            }

            // This is the output of the first task and input to the second
            def translatedOutputs = {
                project.files(javaInputs().collect { file ->
                    return file.path.replace('src/', 'build/dir/')
                })
            }

            // Translates all java files into 'translatedOutputs'
            project.tasks.create(name: 'translateTask', type:Exec) {
                inputs.files javaInputs()
                outputs.files translatedOutputs()

                executable '/bin/echo'
                inputs.files.each { file ->
                    args file.path
                }
            }

            // Compiles 'translatedOutputs' to binary
            project.tasks.create(name: 'compileTask', type:Exec, dependsOn: 'translateTask') {
                inputs.files translatedOutputs()
                outputs.file project.file(project.buildDir.path + '/compiledBinary')

                executable '/bin/echo'
                args compileFlag()
                translatedOutputs().each { file ->
                    args file.path
                }
            }
        }
    }
}

Answer 1

我会以另一种方式看待这个问题。您希望在扩展程序中放置的内容似乎完全由您的每个任务所拥有。如果你有一个“全局”插件配置选项，它是否会被视为输入？

另一种方法是使用您自己的SourceSets并将它们连接到您的自定义任务中。这还不够，IMO。我们仍在将JVM和源代码的本地表示结合在一起。

我建议将Exec任务解压缩为自定义任务，使用@TaskAction来完成繁重任务（即使它只调用project.exec {}）。然后，您可以使用@ Input，@ InputFiles等注释您的输入，并使用@OutputFiles，@ OutputDirectory等输出您的输出。这些注释将帮助自动连接您的依赖项和输入/输出（我认为这是一些战斗即将来临的地方）从）。

你遗漏的另一件事是如果compileFlag影响最终输出，你想要检测它的变化并强制重建（但不是重新翻译）。

我使用Groovy .with method.

简化了插件类的主体

我对此并不完全满意（我认为翻译的文件可能会有所不同），但我希望它能为您展示一些最佳实践。我把它作为一个工作的例子（只要你有一个src / something.java）通过将translate实现为一个复制/重命名而将compile编译为只创建一个'可执行'文件（内容只是输入列表））。我还留下了你的扩展类来演示“全局”插件配置。另外看一下未设置compileFlag会发生什么（我希望错误更好）。

translateTask不会是增量的（尽管我认为you could probably figure out a way to do that）。所以你可能每次都需要删除输出目录。如果你想保持那么简单，我不会将其他输出混合到该目录中。

HTH

apply plugin: 'base'
apply plugin: MyPlugin

class MyTranslateTask extends DefaultTask {
    @InputFiles FileCollection srcFiles
    @OutputDirectory File translatedDir

    @TaskAction
    public void translate() {
        // println "toolhome is ${project.myPluginConfig.toolHome}"
        // translate java files by renaming them
        project.copy {
            includeEmptyDirs = false
            from(srcFiles)
            into(translatedDir)
            rename '(.+).java', '$1.m'
        }
    }
}

class MyCompileTask extends DefaultTask {
    @Input String compileFlag
    @InputFiles FileCollection translatedFiles
    @OutputDirectory File outputDir

    @TaskAction
    public void compile() {
        // write inputs to the executable file
        project.file("$outputDir/executable") << "${project.myPluginConfig.toolHome} $compileFlag ${translatedFiles.collect { it.path }}"  
    }
}

class MyPluginExtension {
    File toolHome = new File("/some/sane/default")
}

class MyPlugin implements Plugin<Project> {
    void apply(Project project) {
        project.with { 
            extensions.create("myPluginConfig", MyPluginExtension)

            tasks.create(name: 'translateTask', type: MyTranslateTask) {
                description = "Translates all java files into translatedDir"
                srcFiles = fileTree(dir: projectDir, includes: [ '**/*.java' ])
                translatedDir = file("${buildDir}/dir")
            }

            tasks.create(name: 'compileTask', type: MyCompileTask) {
                description = "Compiles translated files into outputDir"                
                translatedFiles = fileTree(tasks.translateTask.outputs.files.singleFile) { 
                   includes [ '**/*.m' ]
                   builtBy tasks.translateTask 
                }
                outputDir = file("${buildDir}/compiledBinary")
            }
        }
    }
}

myPluginConfig {
    toolHome = file("/some/custom/path")
}

compileTask { 
  compileFlag = '-flag'
}

Gradle插件针对依赖于扩展对象的任务的最佳实践

1 个答案: