Question

我想对我的一些类应用元编程转换，比如说添加printXxx方法，如下所示：

class Person {
  String name
}

def p = new Person()
p.printName() // does something

我有一个粗略的想法，一旦我有一个元类，如何做到这一点：

Person.metaClass.methodMissing = { name, args ->
  delegate.metaClass."$name" = { println delegate."${getPropName(name)}" }
  delegate."$name"(*args)
}

现在我该如何将此代码转换为可重用的“库”？我想做点什么：

@HasMagicPrinterMethod
class Person {
  String name
}

或

class Person {
  String name

  static {
    addMagicPrinters()
  }
}

Answer 1

定义要添加为特征的行为

trait MagicPrinter {                           
  void printProperties() {  
    this.properties.each { key, val ->
      println "$key = $val"
    }
  }          
}

然后将此特征添加到类

class Person implements MagicPrinter {
  String name
}

现在使用它！

new Person(name: 'bob').printProperties()

Answer 2

你可以采用mixin方法：

class AutoPrint {
    static def methodMissing(obj, String method, args) {
        if (method.startsWith("print")) {
            def property = (method - "print").with { 
                it[0].toLowerCase() + it[1..-1] 
            }
            "${obj.getClass().simpleName} ${obj[property]}"
        }
        else {
            throw new NoSuchMethodException()
        }
    }
}

您可以将其与静态块混合使用：

class Person {
    static { Person.metaClass.mixin AutoPrint }
    String name
}

def p = new Person(name: "john doe")


try {
    p.captain()
    assert false, "should've failed"
} catch (e) {
    assert true
}

assert p.printName() == "Person john doe"

或者使用expandoMetaClass：

class Car {
    String model
}

Car.metaClass.mixin AutoPrint

assert new Car(model: "GT").printModel() == "Car GT"

_{因为7个月后新的'现在'： - ）}

在Groovy中拥有可重用的元类代码的优雅方法是什么？

2 个答案: