Question

我是perl的新手并且坚持以下练习。我有一个多数组，并希望命令它的元素下降到内部数组sum＆＃39; s。我想用Schwartzian变换来做订单。

这是我的载体：

my @vectors = ( [1], [ 1, 2, 3 ], [4], [ 2, 2, 1 ] );

这是预期的载体：

@sorted_vectors = ( [1,2,3], [2,2,1], [4], [1] );

到目前为止，我尝试了这些：

（1）＃！的/ usr / bin中/ perl的

use strict;
use warnings;

use Data::Dumper;

my @vectors = ( [1], [ 1, 2, 3 ], [4], [ 2, 2, 1 ] );

my @sorted_vectors;

  # @sorted_vectors = ( [1,2,3], [2,2,1], [4], [1] );


my %hash=();
for(my $i=0;$i< scalar @vectors;$i++){

$hash{$i}=@vectors[$i];
}


for my $key ( sort { $hash{$b}[1] <=> $hash{$a}[1] } keys %hash ) {
    push(@sorted_vectors,[@{$hash{$key}}]);
}

 print Dumper( \@sorted_vectors );

（2）

#!/usr/bin/perl

use strict;
use warnings;

use Data::Dumper;

my @vectors = ( [1], [ 1, 2, 3 ], [4], [ 2, 2, 1 ] );

my @sorted_vectors;

  # @sorted_vectors = ( [1,2,3], [2,2,1], [4], [1] );


my @sorted = map  { $_->[0] }
          sort { $a->[1] cmp $b->[1] }
          map  { [$_, foo($_)] }
               @vectors;

sub foo{
    my $res = 0;
    foreach my $x (@_) {
        $res+= $x;
    }
    return $res;

}

 print Dumper(\@sorted);

Answer 1

您的代码几乎没有任何改动，

my @sorted = map  { $_->[0] }
      # sort { $a->[1] cmp $b->[1] } # string sort, ascending order
      sort { $b->[1] <=> $a->[1] }   # numeric sort, descending order
      # map  { [$_, foo($_)] }       # foo() expects list, not array reference
      map  { [$_, foo(@$_)] }        # dereferencing $_ aref for foo()
           @vectors;

或同样的事情，但使用核心模块List::Util

中的sum()

use List::Util 'sum';
my @vectors = ( [1], [ 1, 2, 3 ], [4], [ 2, 2, 1 ] );

my @sorted_vectors = map $_->[0],
    sort { $b->[1] <=> $a->[1] }
    map [ $_, sum(@$_) ],
    @vectors;

use Data::Dumper; print Dumper \@sorted_vectors;

输出

Answer 2

List::UtilsBy::rev_nsort_by和List::Util::sum：

很简单

my @vectors = ( [1], [ 1, 2, 3 ], [4], [ 2, 2, 1 ] );

my @sorted = rev_nsort_by { sum @$_ } @vectors;

这对其控制块结果的反向数字顺序（即最大数字首先）的@vectors列表进行排序。这里的控制块简单地总结了每个组件的所有单个元素。

Perl数组顺序

2 个答案: