Question

我喜欢使用Notepad ++，但有一点不断唠叨我的是nppFTP的同步文件夹功能有点过分，但似乎没有办法简单地将当前文件上传到当前的远程目录键盘快捷键，按需。

为“焦点nppFTP窗口”甚至“关于NppFTP”定义了快捷方式选项，但我找不到只需单击“上传文件”按钮的选项。

我已经为很久以前的这个小变化打开了一个功能请求，但似乎没有人注意到。

那么，我如何自己添加快捷方式？也许是AutoHotKey？（通过模拟按钮坐标处的点击，这似乎很容易破解？）

也许有一种简单的方法可以修改NppFTP的源代码或某些XML文件，以便我可以为该按钮分配快捷方式？

谢谢！

Answer 1

如果没有Notepad ++上传脚本，而是使用AHK？我写了一个小ftp函数来完成这项工作：

FtpUploadFile(host,user,pass,sourceFile,destPath:="/",mode:="ascii") {
    Static cmdFile := A_ScriptDir "\FTPCommands.txt"
    Static logFile := A_ScriptDir "\FTPLog.txt"    
    sourceFileFullPath := (InStr(sourceFile,"\") ? sourceFile : A_ScriptDir "\" sourceFile)
    FileDelete %cmdFile%
    FileAppend,  ; The comma is required in this case.
    ( LTrim
        open %host%
        %user%
        %pass%
        %mode%
        cd %destPath%
        put %sourceFileFullPath%
        ls -l
        quit
    ), %cmdFile%
    RunWait %comspec% /c ftp.exe -s:"%cmdFile%" >"%logFile%"
    FileDelete %cmdFile%  ; Delete for security reasons.
    FileRead, logTxt, %logFile%
    FileDelete %logFile%
    Return logTxt
}

F1:: ;press F1 to upload myFile.ahk and myFile.exe
    MsgBox % FtpUploadFile("my.host.com","username","password","myFile.ahk") ;uplaod a text baed file
    MsgBox % FtpUploadFile("my.host.com","username","password","myFile.exe","/","binary") ;upload a binary based file
Return

如果您不想上传日志，请移除MsgBox %。

Notepad ++中的键盘快捷键，用nppFTP上传文件

1 个答案: