Question

我想要做的只是编写Lazy C ++ .lzz文件然后在构建之前运行lzz以生成将在最终应用程序中构建的.cpp和.h文件，有点像moc如何工作Qt的。

有没有办法做到这一点？

Answer 1

以下是如何执行此操作的示例...首先，您需要找到lzz程序，为此使用find_program命令：

find_program(LZZ_COMMAND lzz)

这会将LZZ_COMMAND设置为编译器的路径。然后使用CMake自定义命令将LZZ文件编译为其C ++头文件/实现文件：

add_custom_command(
    OUTPUT ${output}
    COMMAND ${LZZ_COMMAND} -o ${CMAKE_CURRENT_BINARY_DIR} ${filename})

如果您执行的是源外构建，那么会生成当前构建目录中的文件。您还需要指定输出是生成文件：

set_source_files_properties(${output} PROPERTIES GENERATED TRUE)

将它们放在一起，你得到一个类似这样的CMakeLists.txt文件：

cmake_minimum_required(VERSION 2.8)
project(lazy_test)
find_program(LZZ_COMMAND lzz)
function(lazy_compile filename)
    get_filename_component(base ${filename} NAME_WE)
    set(base_abs ${CMAKE_CURRENT_BINARY_DIR}/${base})
    set(output ${base_abs}.cpp ${base_abs}.h)
    add_custom_command(
        OUTPUT ${output}
        COMMAND ${LZZ_COMMAND} -o ${CMAKE_CURRENT_BINARY_DIR} ${filename})
    set_source_files_properties(${output} PROPERTIES GENERATED TRUE)
endfunction()
lazy_compile(${CMAKE_CURRENT_SOURCE_DIR}/example.lzz)
add_executable(test example.cpp example.h)

您可能还希望最终为lzz添加包含路径和其他选项。如果您将所有Lazy C ++内容放入模块文件中，并将其包含在CMakeLists.txt中，那么它会更清晰一些。但这是基本的想法。

Answer 2

我只是想分享我的CMakeLists.txt，它建立在richq的脚本之上。 * .cpp和* .hpp文件现在正确依赖于* .lzz文件。 * .lzz文件被添加到项目中（它回答上面的absense问题），但使用source_group命令与生成的文件分开。

我唯一剩下的交易破坏者是无法编译* .lzz文件的当前文件。

cmake_minimum_required(VERSION 2.8)

PROJECT(LzzTest)

find_program(LZZ_COMMAND lzz.exe)

# Syntax: 
#   add_lzz_file(<output> <lzz file>)
# Adds a build rule for the specified lzz file. The absolute paths of the generated 
# files are added to the <output> list. The files are generated in the binary dir.
# 
# TODO: Support for generating template files etc.
function(add_lzz_file output filename)
  # Only process *.lzz files
  get_filename_component(ext ${filename} EXT)
  if(NOT ext STREQUAL ".lzz")
    return()
  endif()

  set(header_extension "hpp")
  get_filename_component(base ${filename} NAME_WE)
  set(base_abs ${CMAKE_CURRENT_BINARY_DIR}/${base})
  set(outfiles ${base_abs}.cpp ${base_abs}.${header_extension})
  set(${output} ${${output}} ${outfiles} PARENT_SCOPE)

  #message("outfiles=${outfiles}, DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/${filename}")
  add_custom_command(
    OUTPUT ${outfiles}
    COMMAND ${LZZ_COMMAND} 
      -o ${CMAKE_CURRENT_BINARY_DIR} # output dir
      -hx ${header_extension}
      -sl -hl -il -tl -nl -x # insert #line commands w/ absolute paths
      -sd -hd -id -td -nd # don't output files that didn't change
      ${CMAKE_CURRENT_SOURCE_DIR}/${filename}
    DEPENDS "${CMAKE_CURRENT_SOURCE_DIR}/${filename}"
  )

  set_source_files_properties(${outfiles} PROPERTIES GENERATED TRUE)
endfunction()

include_directories(${CMAKE_CURRENT_BINARY_DIR})

set(SOURCES
  A.lzz
  B.lzz
  main.cpp
)

foreach(file ${SOURCES})
  add_lzz_file(GENERATED_SOURCES ${file})
endforeach()

source_group("" FILES ${SOURCES})
source_group(generated FILES ${GENERATED_SOURCES})

add_executable(LzzTest ${SOURCES} ${GENERATED_SOURCES})

Answer 3

对于make：

sourcecode.h sourcecode.cpp: sourcecode.lzz
<TAB>lazy-cpp sourcecode.lzz

使用正确的值填写sourcecode.h，sourcecode.cpp和lazy-cpp。我不认识他们。

如何在cmake中制作构建规则来预处理生成.h和.cpp文件的惰性C ++ .lzz文件？

3 个答案: