Question

我将输出缓冲区中的东西复制到我正在使用的C ++代码中。通常这个输出会陷入字符串。能够自动转义所有控制字符而不是返回并手动编辑粘贴的片段是很好的。

作为一个例子，我可能会复制这样的内容：

error in file "foo.dat"

需要把它变成这样的东西

std::string expected_error = "error in file \"foo.dat\""

我认为可以使用最后一个粘贴的开始和结束标记将替换功能应用于最后一个粘贴的主体，但我不确定如何使其飞行。

更新：

Joey Mazzarelli使用

消化

`[v`]h:%s/\%V"/\\"/g

粘贴后

。

由于没有给出任何解释，我最初发现它有点简洁，但在评论中很难解释，我认为我会解释我认为在这里做的事情：

`[  : Move to start of last paste
v   : Start visual mode
`]  : Move to end of last paste
h   : adjust cursor one position left
:%  : apply on the lines of the selection
s/  : replace
\%V : within the visual area
"   : "
/   : with
\\" : \"
/g  : all occurrences

这似乎是一个很好的方法，但只处理一个字符，“，我希望它能够处理新行，制表符和其他可能会出现在文本中的东西。（可能不是一般的unicode）理解在问题定义中可能并不清楚。

Answer 1

以下是一些vimscript函数，可以执行您想要的操作。

EscapeText()将任意文本转换为C转义的等效文本。它会将换行符转换为\n，制表符转换为\t，将Control + G转换为\a等，并为非特殊字符生成八进制转义符（如\o032）有一个友好的名字。
PasteEscapedRegister()转义v:register命名的寄存器的内容，然后将其插入当前缓冲区。（当函数返回时，寄存器将被恢复，因此可以重复调用该函数，而无需多次转发寄存器内容。）

还包含一些关键映射，使PasteEscapedRegister()易于交互使用。 <Leader>P粘贴在光标位置之前转储寄存器内容，然后粘贴<Leader>p。两者都可以使用寄存器规范作为前缀，例如"a\P来粘贴寄存器a的转义内容。

以下是代码：

function! EscapeText(text)

    let l:escaped_text = a:text

    " Map characters to named C backslash escapes. Normally, single-quoted
    " strings don't require double-backslashing, but these are necessary
    " to make the substitute() call below work properly.
    "
    let l:charmap = {
    \   '"'     : '\\"',
    \   "'"     : '\\''',
    \   "\n"    : '\\n',
    \   "\r"    : '\\r',
    \   "\b"    : '\\b',
    \   "\t"    : '\\t',
    \   "\x07"  : '\\a',
    \   "\x0B"  : '\\v',
    \   "\f"    : '\\f',
    \   }

    " Escape any existing backslashes in the text first, before
    " generating new ones. (Vim dictionaries iterate in arbitrary order,
    " so this step can't be combined with the items() loop below.)
    "
    let l:escaped_text = substitute(l:escaped_text, "\\", '\\\', 'g')

    " Replace actual returns, newlines, tabs, etc., with their escaped
    " representations.
    "
    for [original, escaped] in items(charmap)
        let l:escaped_text = substitute(l:escaped_text, original, escaped, 'g')
    endfor

    " Replace any other character that isn't a letter, number,
    " punctuation, or space with a 3-digit octal escape sequence. (Octal
    " is used instead of hex, since octal escapes terminate after 3
    " digits. C allows hex escapes of any length, so it's possible for
    " them to run up against subsequent characters that might be valid
    " hex digits.)
    "
    let l:escaped_text = substitute(l:escaped_text,
    \   '\([^[:alnum:][:punct:] ]\)',
    \   '\="\\o" . printf("%03o",char2nr(submatch(1)))',
    \   'g')

    return l:escaped_text

endfunction


function! PasteEscapedRegister(where)

    " Remember current register name, contents, and type,
    " so they can be restored once we're done.
    "
    let l:save_reg_name     = v:register
    let l:save_reg_contents = getreg(l:save_reg_name, 1)
    let l:save_reg_type     = getregtype(l:save_reg_name)

    echo "register: [" . l:save_reg_name . "] type: [" . l:save_reg_type . "]"

    " Replace the contents of the register with the escaped text, and set the
    " type to characterwise (so pasting into an existing double-quoted string,
    " for example, will work as expected).
    " 
    call setreg(l:save_reg_name, EscapeText(getreg(l:save_reg_name)), "c")

    " Build the appropriate normal-mode paste command.
    " 
    let l:cmd = 'normal "' . l:save_reg_name . (a:where == "before" ? "P" : "p")

    " Insert the escaped register contents.
    "
    exec l:cmd

    " Restore the register to its original value and type.
    " 
    call setreg(l:save_reg_name, l:save_reg_contents, l:save_reg_type)

endfunction

" Define keymaps to paste escaped text before or after the cursor.
"
nmap <Leader>P :call PasteEscapedRegister("before")<cr>
nmap <Leader>p :call PasteEscapedRegister("after")<cr>

Answer 2

这至少可以让你开始......

粘贴后：

`[v`]h:%s/\%V"/\\"/g

显然，您可以将其映射到更容易输入的内容。

Answer 3

虽然Joeys解决方案看起来可能是可扩展的，以涵盖我需要的所有情况，但我认为我将使用vims python集成分享我的部分解决方案（因为我对python比vim脚本更熟悉）

# FILE : tocstring.py
import vim
def setRegister(reg, value):
  vim.command( "let @%s='%s'" % (reg, value.replace("'","''") ) )

def getRegister(reg):
  return vim.eval("@%s" % reg )

def transformChar( map, c):
  if c in map:
    return map[c]
  return c

def transformText( map, text ):
  return ''.join( [ transformChar(map,c) for c in text ] )

cmap={}
cmap["\\"]="\\\\"
cmap["\n"]="\\n" 
cmap["\t"]=r"\\t"
cmap['"']="\\\""

def convertToCString( inregister, outregister ):
  setRegister(outregister, transformText( cmap, getRegister(inregister) ) )

然后在我的.vimrc或其他conf文件中我可以放

# FILE cpp.vim
python import tocstring
# C-Escape and paste the currently yanked content
nmap <Leader>P :python tocstring.convertToCString("@","z")<CR>"zP
# C-Escape and paste the current visual selection
vmap <Leader>P "zd:python tocstring.convertToCString("z","z")<CR>"zP

如果我可以使第一个函数工作以便“a \ P粘贴”a“寄存器的转换内容，我会认为这是可行的，使用v：register以某种方式注册，但它逃脱了我。 / p>

这个版本的工作方式与Joeys解决方案可以像

一样工作

nmap <Leader>P `[v`]"zd:python tocstring.convertToCString("z","z")<CR>"zP

致谢：这使用来自Can you access registers from python functions in vim的代码与来自vims python的寄存器进行交互

Answer 4

对于Java / JavaScript类型的转义，可以使用json_encode

nmap <leader>jp :call setreg('e', json_encode(@+))\| normal "ep<CR>

json_encode(@+)-JSON编码寄存器+的内容（映射到剪贴板）

setreg('e',...)-将其写入寄存器e

normal "ep-粘贴寄存器e

的内容

在vim中粘贴时转义字符

4 个答案: