Question

我想列出Windows使用Windows Indexing Service索引的所有文件。

指定的文件扩展名是可以接受的。

例如：我正在使用一种软件来呈现用户媒体，如照片和视频。我目前正在使用以下自定义过程来自行查找文件：

function FindAllFiles_Safe(aDirectory, aFilter: string; aIncludeSubDirs: boolean): string;
  {$IFDEF DCC}
  var TD: TDirectory;
      SO: TSearchOption;
      DF: TStringDynArray;
      i: integer;
      sl: TStringList;

      MaskArray: TStringDynArray;
      Predicate: TDirectory.TFilterPredicate;
      {$ENDIF}
begin
  {$IFDEF FPC}
  result:=FindAllFiles(aDirectory,aFilter,aIncludeSubDirs).text;
  {$ENDIF}

  {$IFDEF DCC}
  MaskArray := SplitString(aFilter, ';');


  if aIncludeSubDirs=true then SO:=TSearchOption.soAllDirectories;

  Predicate :=
    function(const Path: string; const SearchRec: TSearchRec): Boolean
      var Mask: string;
    begin
      for Mask in MaskArray do
        if MatchesMask(SearchRec.Name, Mask) then
          exit(True);
      exit(False);
    end;

   //DF:=TD.GetFiles(aDirectory, Predicate, SO);
   DF:=TD.GetFiles(aDirectory, SO, Predicate);

   if length(DF)=0 then exit;


   sl:=TStringList.Create;
   for i := 0 to length(DF)-1 do sl.Add(DF[i]);

  result:=sl.Text;
  sl.Free;

  {$ENDIF}
end;

有没有办法访问Windows已编入索引的文件？
我想利用Windows索引服务快速检索文件，而不是浪费资源，如果Windows之前已经完成过。

Answer 1

query the index of the Windows Search的一种方法是使用ADO和查询语法（AQS）和SQL。

尝试此示例代码（当然，您可以改进SQL语句以过滤并加快结果）

{$APPTYPE CONSOLE}

{$R *.res}

uses
  ADOInt,
  SysUtils,
  ActiveX,
  ComObj,
  Variants;


procedure  QuerySystemIndex;
var
  Connection : _Connection;
  RecordSet: _RecordSet;
  v: Variant;
begin;
  OleCheck(CoCreateInstance(CLASS_Connection, nil, CLSCTX_ALL, IID__Connection, Connection));
  OleCheck(CoCreateInstance(CLASS_RecordSet, nil, CLSCTX_ALL, IID__RecordSet, RecordSet));
  Connection.CursorLocation := adUseClient;
  Connection.Open('Provider=Search.CollatorDSO;Extended Properties=''Application=Windows'';', '', '', adConnectUnspecified);
  Recordset.Open('SELECT Top 5 System.ItemPathDisplay FROM SYSTEMINDEX', Connection, adOpenForwardOnly, adLockReadOnly, adCmdText);
  Recordset.MoveFirst;
  v:='System.ItemPathDisplay';
  while not Recordset.EOF do
   begin
      Writeln(Recordset.Fields.Item[v].Value);
      Recordset.MoveNext();
   end;
end;


begin
 try
    CoInitialize(nil);
    try
      QuerySystemIndex;
    finally
      CoUninitialize;
    end;
 except
    on E:EOleException do
        Writeln(Format('EOleException %s %x', [E.Message,E.ErrorCode]));
    on E:Exception do
        Writeln(E.Classname, ':', E.Message);
 end;
 Writeln('Press Enter to exit');
 Readln;
end.

您可以找到替代方法来访问MSDN documentation上的搜索索引。

Answer 2

There is an API for Windows Search（以前称为Windows桌面搜索）。

然而，虽然Windows Search API无疑具有非常强大的功能，但我认为只需根据文件扩展名（甚至文件名中的其他组成元素）定位文件，Windows Search API可能会过于复杂并且提供的优势可以忽略不计除非你正在处理真正特别多的文件。

使用Delphi获取Windows中所有索引文件的列表

2 个答案: