Question

我开发了一个谓词，用Index替换列表List的索引Value的值，并创建一个新的更新列表NewList。

%replace(List,Index,Value,NewList)

replace([_|T], 0, X, [X|T]).
replace([H|T], I, X, [H|R]):-
        I > -1, 
        NI is I-1,
        replace(T, NI, X, R), !.
replace(L, _, _, L).

谓词在常规列表上运行正常，但是我想让它在列表列表中工作，我有点坚持一步。

subs([]).
subs([Head|Tail], Index) :-
        replace((Head), Index, 'r', Board2),
        printRow(Board2),
        subs(Tail).

原始列表：

[ [  0 ,  1 ,  2 ,  3 ,  4 ] ,
  [  5 ,  6 ,  7 ,  8 ,  9 ] ,
  [ 10 , 11 , 12 , 13 , 14 ] ,  
  [ 15 , 16 , 17 , 18 , 19 ] ,  
  [ 20 , 21 , 22 , 23 , 23 ]
]

输出：

[ [  0 , r ,  2 ,  3 ,  4 ] ,  
  [  5 , r ,  7 ,  8 ,  9 ] ,  
  [ 10 , r , 12 , 13 , 14 ] ,  
  [ 15 , r , 17 , 18 , 19 ] ,  
  [ 20 , r , 22 , 23 , 23 ]
]

值得注意的是，为什么会发生这种情况，因为它会将值替换为每个子列表中的Index = 1。为了解决这个问题，我考虑过实施一个计数器。通过每次迭代（每个子列表的大小）将索引递增5，谓词现在应该输出以下（所需）列表：

期望输出：

[ [  0 ,  r ,  2 ,  3 ,  4 ] ,
  [  5 ,  6 ,  7 ,  8 ,  9 ] ,
  [ 10 , 11 , 12 , 13 , 14 ] ,  
  [ 15 , 16 , 17 , 18 , 19 ] ,
  [ 20 , 21 , 22 , 23 , 23 ]
]

问题在于如何实施这个非常反击。代码看起来应如下所示，但有些东西我错过了：

subs([]).
subs([Head|Tail], Index) :-
        replace((Head), Index, 'r', Board2),
        printRow(Board2),
        Index is Index + 5
        subs(Tail, Index).

输出： subs(<Original List>, 7).

0  1  2  3  4

有人可以帮我解决一下如何实施吗？

Answer 1

你的问题陈述有点不清楚。

从您的示例中，您希望将列表列表视为二维数组，并替换该数组中的单个单元格。如果是这样，这是一种方式（可能是非最佳的）：

%
% replace a single cell in a list-of-lists
% - the source list-of-lists is L
% - The cell to be replaced is indicated with a row offset (X)
%   and a column offset within the row (Y)
% - The replacement value is Z
% - the transformed list-of-lists (result) is R
%
replace( L , X , Y , Z , R ) :-
  append(RowPfx,[Row|RowSfx],L),     % decompose the list-of-lists into a prefix, a list and a suffix
  length(RowPfx,X) ,                 % check the prefix length: do we have the desired list?
  append(ColPfx,[_|ColSfx],Row) ,    % decompose that row into a prefix, a column and a suffix
  length(ColPfx,Y) ,                 % check the prefix length: do we have the desired column?
  append(ColPfx,[Z|ColSfx],RowNew) , % if so, replace the column with its new value
  append(RowPfx,[RowNew|RowSfx],R)   % and assemble the transformed list-of-lists
  .

另一种方式（可能更优化）：

replace( [L|Ls] , 0 , Y , Z , [R|Ls] ) :- % once we find the desired row,
  replace_column(L,Y,Z,R)                 % - we replace specified column, and we're done.
  .                                       %
replace( [L|Ls] , X , Y , Z , [L|Rs] ) :- % if we haven't found the desired row yet
  X > 0 ,                                 % - and the row offset is positive,
  X1 is X-1 ,                             % - we decrement the row offset
  replace( Ls , X1 , Y , Z , Rs )         % - and recurse down
  .                                       %

replace_column( [_|Cs] , 0 , Z , [Z|Cs] ) .  % once we find the specified offset, just make the substitution and finish up.
replace_column( [C|Cs] , Y , Z , [C|Rs] ) :- % otherwise,
  Y > 0 ,                                    % - assuming that the column offset is positive,
  Y1 is Y-1 ,                                % - we decrement it
  replace_column( Cs , Y1 , Z , Rs )         % - and recurse down.
  .                                          %

替换列表PROLOG中的元素

1 个答案: