Question

我的程序需要接受3个输入，然后检查它们是否形成毕达哥拉斯三重奏。我正在使用小人计算机来执行此操作，因此我正在使用LMC程序集。如果您想了解可以使用的命令的更多信息，或者下载我正在使用的模拟器，here is the link

这是我到目前为止编写的代码。

#Valid mnemonics are:
# HLT, ADD, SUB, STO, LDA,
# BR, BRZ, BRP, IN, OUT, DAT
# The first part of the program will sort a,b and c, so that they will always be in order from
# a,b,c                                  



        IN      #get first input
        STO c   
        IN      #get second input   
        STO b
        IN      #get third input
        STO a

        SUB b   #Test if a>b
        BRP swapAB
        BR next1

swapAB  LDA b   #Swaps a and b
        STO temp
        LDA a
        STO b
        LDA temp
        STO a   #continues on to next1

next1   LDA b   #Test if b>c
        SUB c
        BRP swapBC
        BR end  #All sorted

swapBC  LDA c   #Swaps b an c
        STO temp
        LDA b
        STO c
        LDA temp
        STO b
        BR next2

next2   LDA a   #tests new a>b
        SUB b
        BRP swapAB  


end     LDA a   #begin the process of squaring a
        STO total
        SUB one
        STO count
loop1   LDA total
        ADD a
        STO total
        LDA count
        SUB one
        STO count
        BRZ endsq1
        BR loop1

endsq1  LDA total
        STO d   #stores a*a in d
        OUT #for testing. Outputs a*a
        SUB total
        STO total   

         LDA b  #Begins squaring b
         STO total
         SUB one
         STO count
loop2    LDA total
         ADD b
         STO total
         LDA count
         SUB one
         STO count
         BRZ endsq2
         BR loop2   #end of squaring b

endsq2   LDA total
         STO e  #stores b*b in e
         OUT
         SUB total
         STO total

         LDA c  #begin squaring c
         STO total
         SUB one
         STO count
 loop3   LDA total
         ADD c
         STO total
         LDA count
         SUB one
         STO count
         BRZ endsq3
         BR loop3   #end squaring c

         endsq3 LDA total
         STO f  #stores c*c in f
         OUT
         SUB total
         STO total

         LDA d  #begin check a^2 + b^2 = c^2
         ADD e
         SUB f
         BRZ true
         LDA count
         OUT    #FALSE output 000
         HLT
true     LDA one    
         OUT    #TRUE output 001
         HLT

a        DAT
b        DAT
c        DAT
d        DAT
e        DAT
f        DAT
temp     DAT
total    DAT 000
one      DAT 001
count    DAT 000

如果a，b，c形成毕达哥拉斯三重奏，则程序将输出001，否则输出000。但是，如果发生溢出，它也需要输出002，即输入超过LMC 3位数限制。

我知道代码适用于检查a，b，c是否是毕达哥拉斯三元组。但是，我需要一些检查溢出的方法（LMC只接受3位数值）。为了使这更难，我正在使用的LMC版本上没有溢出标志。我的想法是检查c＆gt;如图31所示，当31以上的任何值在平方时将大于1000，并以某种方式检查是否^ 2 + b ^ 2> 1000。

为了进一步复杂化，LMC只有99个内存地址来存储数据和指令，而我只剩下5-6个。无论如何我可以简化上面的代码来减少程序指令占用的内存量吗？我原本以为我可以在平方过程中使用一个循环，但是我不知道如何分支以便每次都将结果保存在不同的变量中。

非常感谢任何帮助。

更新：这是插入排序lmc代码工作

inloop  IN # get a number
        STO tmp
        SUB range #check input < 31 
        BRP error
        LDA tmp
        SUB c # bigger than the biggest so far?
        BRP storeC
        LDA b
        BRZ storeB # if empty, use b
        LDA tmp    # must use a
        STO a
        BR minus
storeB  LDA tmp
        STO b
        BR minus
storeC  LDA b
        BRZ fillB # if empty, use b
        BR fillA  # otherwise, use a
fillB   LDA c    
        STO b
        LDA tmp
        STO c
        BR minus
fillA   LDA c 
        STO a
        LDA tmp
        STO c
        BR minus   
minus   LDA incount
        SUB one
        BRZ next
        STO incount
        BR inloop
next    LDA a
        OUT
        LDA b
        OUT
        LDA c
        OUT
        HLT
error   LDA overflow
        OUT
        HLT

range   DAT 031
a   DAT 000
b   DAT 000
c   DAT 000
tmp DAT
overflow DAT 002
incount DAT 003
one DAT 001

Answer 1

一旦您知道单个方块有效，您可以将方程式重新排列为c^2 - a^2 - b^2 = 0。您可以测试该相等性，同时还测试信号溢出的负标志。

要压缩代码，您确实可以创建一个循环来读取并对数字进行平方并将其放置到位。由于您无论如何都在对数字进行排序，因此您并不真正关心它们的输入顺序。您可以使用插入排序算法，确保3个数据位置初始化为零。

更新：这里是示例代码，显示了循环体的大致轮廓：

        IN # get a number
        STO tmp
        # do range check here
        SUB c # bigger than the biggest so far?
        BRP storeC
store   LDA b
        BRZ storeB # if empty, use b
        LDA tmp    # must use a
        STO a
        BR next
storeB  LDA tmp
        STA b
        BR next
storeC  LDA c
        STO tmp2
        LDA tmp    # store new number
        STO c      # as biggest
        LDA tmp2   # insert previous biggest
        STO tmp
        BR store
next    # repeat until we got 3 numbers (use a counter)

注意我已经对它进行了一些优化，因为我们只需要知道哪个是最大的数字（进入c），但a和b的关系不是'无所谓。我希望这有效，我还没有测试过。

LMC - 有效地检查小人计算机组件中是否^ 2 + b ^ 2 = c ^ 2

1 个答案: