Question

我多年来一直使用Indy通过FTP传输文件，但未能找到满意的解决方案来解决以下问题。

当用户在路由器后面上传大文件时，有时会发生以下情况：文件上传正常，但同时命令通道因超时而断开连接。通常，直接连接到服务器不会发生这种情况，因为服务器“知道”正在数据通道上进行传输。但是有些路由器并不知道这一点，并且命令通道已关闭。

许多程序会定期发送NOOP命令，以使命令通道保持活动状态，即使这不是标准FTP规范的一部分。我的问题：我该怎么做？我是否在OnWork事件中发送NOOP命令？这是否会以某种方式造成任何附带损害，例如，我是否需要处理某些响应？我如何才能最好地解决这个问题？

Answer 1

我们使用几种方法来处理这个问题：（1）在传输过程中在控制通道上启用TCP/IP keepalives，以及（2）在连接断开后正常恢复，（3）支持恢复损坏的传输。

许多FTP客户端会在一切都空闲时发送NOOP，但我不知道是否有任何在数据传输过程中发送它们，因为在这种情况下你需要处理响应，许多服务器都不会发送他们回来，直到数据完成转移。

Indy 10.5.8（Delphi XE2）支持TCP / IP本机保持alives。只需使用TIdFTP的NATKeepAlive属性。

对于以前的版本，请分配OnDataChannelCreate / OnDataChannelDestroy事件：

const
  KeepAliveIdle = 2 * SecsPerMin;
  KeepAliveInterval = 2 * SecsPerMin;
  IOC_VENDOR = $18000000;
  SIO_KEEPALIVE_VALS = DWORD(IOC_IN or IOC_VENDOR or 4);

type
  tcp_keepalive = record
    onoff: u_long;
    keepalivetime: u_long;
    keepaliveinterval: u_long;
  end;

procedure TFtpConnection.DataChannelCreated(Sender: TObject;
  ADataChannel: TIdTCPConnection);
var
  Socket: TIdSocketHandle;
  ka: tcp_keepalive;
  Bytes: DWORD;
begin
  // Enable/disable TCP/IP keepalives.  They're very small (40-byte) packages
  // and will be sent every KeepAliveInterval seconds after the connection has
  // been idle for KeepAliveIdle seconds.  In Win9x/NT4 the idle and timeout
  // values are system wide and have to be set in the registry;  the default is
  // idle = 2 hours, interval = 1 second.
  Socket := (FIdFTP.IOHandler as TIdIOHandlerSocket).Binding;
  if Win32MajorVersion >= 5 then begin
    ka.onoff := 1;
    ka.keepalivetime := KeepAliveIdle * MSecsPerSec;
    ka.keepaliveinterval := KeepAliveInterval * MSecsPerSec;
    WSAIoctl(Socket.Handle, SIO_KEEPALIVE_VALS, @ka, SizeOf(ka), nil, 0, @Bytes,
      nil, nil)
  end
  else
    Socket.SetSockOpt(Id_SOL_SOCKET, Id_SO_KEEPALIVE, Id_SO_True)
end;

procedure TFtpConnection.DataChannelDestroy(ASender: TObject;
  ADataChannel: TIdTCPConnection);
var
  Socket: TIdSocketHandle;
begin
  Socket := (FIdFTP.IOHandler as TIdIOHandlerSocket).Binding;
  Socket.SetSockOpt(Id_SOL_SOCKET, Id_SO_KEEPALIVE, Id_SO_False)
end;

要成功传输文件，要正常恢复，只需在最后重新连接并执行 SIZE 或 LIST 以获取文件大小。如果匹配则文件已成功传输，您无需执行任何其他操作。如果服务器支持它，您还可以发送 XCRC 命令来获取CRC值，以便将其与本地文件进行比较。
如果您想要非常健壮，还可以查看TIdFTP.CanResume。如果已设置，则服务器支持 REST 命令，因此您可以通过将true传递到AResume TIdFTP.Get/Put参数来接收上次停止的位置。

Indy FTP，大文件和NAT路由器

1 个答案: