Question

我尝试使用GLib的GenericArray，Slist，List进行一些排序。使用sort_with_data进行排序可以正常工作，但是当我尝试使用Glib Array时，它不起作用，或者说它做了不同的事情！

这是整数的排序函数：

[indent=4]

init
    var a = new Array of int
    for i in new array of int = {3, 2, 1, 5, 7}
        a.append_val (i)

    a.sort_with_data (my_func)
    for var i = 0 to (a.length - 1)
        stdout.printf ("%d, ", a.index (i))
    // 3, 2, 1, 5, 7, 
    stdout.putc ('\n')

    a.sort (my_func)
    for var i = 0 to (a.length - 1)
        stdout.printf ("%d, ", a.index (i))
    // 3, 2, 1, 5, 7, 

def my_func (a: int, b: int): int
    return a - b

输出是 3,2,1,5,7，

我不知道出了什么问题。请不要告诉我使用 Gee ！我的问题是sort 数组int 谢谢！

Answer 1

a.length - b.length将按长度而非内容对字符串进行排序。如果您需要内容，请使用a.collate(b)。

Answer 2

GenericArray的排序函数更容易编写。但阵列的排序功能不同。

排序int数据和排序字符串数据的示例

[indent=4]

init
    var a = new Array of int
    var b = new array of int = {3, 8, 6, 5, 7, 4, 1, 2}
    a.append_vals (b, b.length)

    // sort_with_data
    a.sort_with_data ((CompareDataFunc) int_sort)
    stdout.puts ("sort_with_data:\n")

    for var i = 0 to (a.length - 1)
        stdout.printf ("%d, ", a.index (i))
    stdout.putc ('\n')

    // sort
    a.sort ((CompareFunc) int_sort)
    stdout.puts ("sort:\n")

    for var i = 0 to (a.length - 1)
        stdout.printf ("%d, ", a.index (i))

    stdout.puts ("\nsort string:\n")
    // sort string
    var S = new array of string = {
        "zee", "app", "april", "bana", "grap", "oliv", "lim", "apri"
    }

    var T = new Array of string
    T.append_vals (S, S.length)

    T.sort ((CompareFunc) str_sort)

    for var i = 0 to (T.length - 1)
        stdout.printf ("%s, ", T.index (i))

    // app, apri, bana, grap, lim, oliv, zee, 

def int_sort (a: int*, b: int*): int
    return *a - *b

def str_sort (a: char**, b: char**): int
    return strcmp ((string)(*a), (string)(*b))


/* ouput

sort_with_data:
1, 2, 3, 4, 5, 6, 7, 8, 
sort:
1, 2, 3, 4, 5, 6, 7, 8, 
sort string:
app, apri, april, bana, grap, lim, oliv, zee, 

*/

GLIb数组排序，如何排序？

2 个答案: