Question

我想覆盖Haskell中的默认整数构造函数，因此它们会产生字符串（主要是为了好奇，但暂时为LaTeX的\ frac {} {}带来不便的输入替换。

我希望能够使用语言本身，而不是使用特殊的解析器，但我想这可能不会有用......

module Main where

import Prelude hiding ((+))

newtype A = A Int deriving (Eq, Show, Num)
default (A)

(+) :: A -> (A -> String)
(A a) + (A b) = (show a) ++ " + " ++ (show b)

main2 = 3+4

main :: IO ()
main = putStrLn main2

上面的问题是+函数只适用于（A，A）而不是（A，String）等。如果只是遗漏模式匹配“（A a）”并写“a”相反，然后show（）函数前置“A”，所以“3”变成“A 3”而不是“3”。

我想覆盖Show for A，但似乎很头疼...

Answer 1

如果您想要Show个A实例，那么就不要派生它并创建自己的实例：

newtype A = A Int deriving (Eq, Num)

instance Show A where
  show (A a) = show a

然后你可以这样写：

(+) :: (Show a, Show b) => a -> b -> String
a + b = show a ++ " + " ++ show b

当然，如果您要定义自己的+运算符，那么我认为您的问题不需要newtype A声明：

module Main where

import Prelude hiding ((+))

(+) :: (Show a, Show b) => a -> b -> String
a + b = show a ++ " + " ++ show b

aSum = 3 + 4

main :: IO ()
main = putStrLn aSum

Answer 2

覆盖Haskell中的默认整数构造函数，因此它们生成字符串

所以这是通过为String定义Num实例来完成的。那么（+）可以用作String - ＆gt;字符串 - ＆gt;字符串。

一个超级简单的例子：

{-# LANGUAGE TypeSynonymInstances #-}

module A where

instance Num String where (+) = (++)

{-

*A> "hello" + "world"
"helloworld"

-}

编写fromIntegral方法以从整数文字到字符串获取函数（例如1 - ＆gt;“1”）。

对于将Num值列表提升为Num的更通用，更有纪律的方法，请将流的Hinze方法视为Num，http://hackage.haskell.org/package/hinze-streams

Answer 3

这是你想要做的吗？创建一个数字类型，以便您可以在Haskell中编写表达式，然后只打印它们并将它们作为LaTeX数学字符串出现？

module Main where

import Data.Ratio

data LaTeXmath = E Precedence String
    deriving (Eq)

data Precedence = Pterm | Pmul | Padd | Pexp
    deriving (Show, Eq, Ord, Bounded)

expr :: Precedence -> LaTeXmath -> String
expr p (E q s) | p >= q    = s
               | otherwise = "\\left(" ++ s ++ "\\right)"

instance Num LaTeXmath where
    a + b = E Padd (expr Padd a ++ " + " ++ expr Padd b)
    a - b = E Padd (expr Padd a ++ " - " ++ expr Padd b)
    a * b = E Pmul (expr Pmul a ++ " "   ++ expr Pmul b)

    negate a = E Pterm (" -" ++ expr Pterm a)
    abs    a = E Pterm (" |" ++ expr Pexp a ++ "| ")
    signum a = E Pterm (" \\signum (" ++ expr Pexp a ++ ") ")

    fromInteger i = E Pterm (show i)

instance Fractional LaTeXmath where
    a / b = E Pterm ("\\frac{" ++ expr Pexp a ++ "}{" ++ expr Pexp b ++ "}")

    fromRational r = fromInteger num / fromInteger denom
        where num = numerator r
              denom = denominator r

instance Show LaTeXmath where
    show a = "\\[" ++ expr Pexp a ++ "\\]"

sym :: String -> LaTeXmath
sym x = E Pterm x

anExample :: LaTeXmath
anExample = sym "y" / (recip 2 * ( 3 + sym "x" + 2 * sym "y" ) )

main :: IO ()
main = print anExample

处理优先级所需的逻辑使得正确插入括号变得复杂。打印出来的例子：

\[\frac{y}{\frac{1}{2} \left(3 + x + 2 y\right)}\]

如何覆盖新类型的显示？

3 个答案: