Question

我正在学习Clojure，并希望更多地了解序列。我有一个现实生活中的问题，我已经减少为一般的问题，但我不知道它是否具有规范名称。希望下面的例子清楚地表明了这一点。

假设我有两个向量，src和dst。 src向量中的项目本身就是向量，我需要将每个向量中的每个项目映射到dst中的相应值。

(def src [ ["a1" "a2" "a3"] ["b1" "b2"] ["c1" "c2" "c3" "c4"] ])
(def dst [ "a" "b" "c" ])

我想制作以下地图：

{ :a1 "a", :a2 "a", :a3 "a", :b1 "b", :b2 "b", :c1 "c", :c2 "c", :c3 "c", :c4 "c" }

我可以在Python中做到这一点，但Clojure的做法对我来说并不清楚。对于这个问题，我可以构建一个地图，但我希望能够以通用的方式进行，而不仅仅是为了这个实例。

在Python中，这将是：

src = [['a1', 'a2', 'a3'], ['b1', 'b2'], ['c1', 'c2', 'c3', 'c4']]
dst = ['a', 'b', 'c']
result = {}
for (s, d) in zip(src, dst):
    for x in s:
        result[x] = d

在Clojure中，我尝试过：

(interleave src dst)
;=> (["a1" "a2"] "a" ["b1" "b2" "b3"] "b" ["c1"] "c")

所以我把矢量弄平了，但我不知道如何迭代地图键，然后选择值。

另外，zipmap并不能让我自己走得太远：

(zipmap src (map keyword dst))
;=> {["c1"] :c, ["b1" "b2" "b3"] :b, ["a1" "a2"] :a}
;bogus result

现在我需要翻转地图键和值，然后仍然迭代。

我还没有成功构建for表达式：

(for [s src] (zipmap s dst)))
;=> ({"a2" "b", "a1" "a"} {"b3" "c", "b2" "b", "b1" "a"} {"c1" "a"})
;bogus result

我接近问题是将两个向量配对，但我似乎无法将src向量中的向量放到位置，这样我就可以简单地zipmap每个其中dst。

我怀疑答案非常明显，但我的大脑仍然没有足够的功能。也许某处有into {}和/或assoc。

任何指针？如果您有兴趣，我提到的现实问题是从RNA密码子到氨基酸的映射。

Answer 1

user> (into {}
            (for [[sources, dest] (map list src dst),
                  source sources]
                 [(keyword source), dest]))
{:a2 "a", :b2 "b", :c3 "c", :a3 "a", :a1 "a", :b1 "b", :c4 "c", :c2 "c", :c1 "c"}

for理解创建每个源/目标对，然后into用于填充这些对中的哈希映射。

Answer 2

map可以使多个seq迭代，例如：

(map + [1 2 3] [4 5 6])
;; => (5 7 9)

因此，这将是您要将处理的值转换为同一函数的方法，从而导致处理对["a1" "a2" "a3"] / "a"等等...

(map
  (fn [src dst]
    ???)
  [["a1" "a2" "a3"] ["b1" "b2"] ["c1" "c2" "c3" "c4"]]
  ["a" "b" "c"])

zipmap获取一系列键（我们拥有）和一系列值（我们必须从单个值构造）。 repeat可用于基于常量值创建无限懒惰seq：

(take 3 (repeat "a"))
;; => ("a" "a" "a")

和

(zipmap ["a1" "a2" "a3"] (repeat "a"))
;; => {"a3" "a", "a2" "a", "a1" "a"}

这使原始代码看起来像这样：

(map
  (fn [src dst]
    (zipmap src (repeat dst)))
  [["a1" "a2" "a3"] ["b1" "b2"] ["c1" "c2" "c3" "c4"]]
  ["a" "b" "c"])
;; => ({"a3" "a", "a2" "a", "a1" "a"} {"b2" "b", "b1" "b"} {"c4" "c", "c3" "c", "c2" "c", "c1" "c"})

最后，您可以使用into将所有这些地图合并为一个地图，从而生成最后一段代码：

(into {} (map #(zipmap %1 (repeat %2)) src dst))
;; => {"a3" "a", "c2" "c", "c3" "c", "a1" "a", "b2" "b", "c4" "c", "a2" "a", "c1" "c", "b1" "b"}

Answer 3

(into {} (mapcat (fn [ss d] (map #(vector (keyword %) d) ss)) src dst))

;{:a3 "a", :c1 "c", :c2 "c", :b2 "b",
; :b1 "b", :c4 "c", :c3 "c", :a2 "a", :a1 "a"}

...但我更喜欢@noisesmith's - for在这里更好。

如何将嵌套向量中的项与Clojure中相应的单个值配对？

3 个答案: