Question

我需要在运行时将ID和密码传递给批处理文件，而不是将它们硬编码到文件中。

这是命令行的样子：

test.cmd admin P@55w0rd > test-log.txt

Answer 1

另一个有用的提示是使用%*来表示“全部”。例如：

echo off
set arg1=%1
set arg2=%2
shift
shift
fake-command /u %arg1% /p %arg2% %*

当你跑步时：

test-command admin password foo bar

上面的批处理文件将运行：

fake-command /u admin /p password admin password foo bar

我的语法可能略有错误，但这是一般的想法。

Answer 2

我是这样做的：

@fake-command /u %1 /p %2

这是命令的样子：

test.cmd admin P@55w0rd > test-log.txt

%1适用于第一个参数%2（这里是棘手的部分）适用于第二个参数。您最多可以以这种方式传递9个参数。

Answer 3

如果您想要智能地处理缺失的参数，您可以执行以下操作：

IF %1.==. GOTO No1
IF %2.==. GOTO No2
... do stuff...
GOTO End1

:No1
  ECHO No param 1
GOTO End1
:No2
  ECHO No param 2
GOTO End1

:End1

Answer 4

使用％1，％2，...％9或％*，
来访问批处理参数可以很简单但只有内容很简单。

对于像"&"^&这样的复杂内容，没有简单的方法，因为在不产生错误的情况下无法访问％1。

set  var=%1
set "var=%1"
set  var=%~1
set "var=%~1"

线条扩展为

set  var="&"&
set "var="&"&"
set  var="&"&
set "var="&"&"

每一行都失败了，因为其中一个&在引号之外。

可以通过从临时文件中读取标记版本的参数来解决此问题。

@echo off
SETLOCAL DisableDelayedExpansion

SETLOCAL
for %%a in (1) do (
    set "prompt="
    echo on
    for %%b in (1) do rem * #%1#
    @echo off
) > param.txt
ENDLOCAL

for /F "delims=" %%L in (param.txt) do (
  set "param1=%%L"
)
SETLOCAL EnableDelayedExpansion
set "param1=!param1:*#=!"
set "param1=!param1:~0,-2!"
echo %%1 is '!param1!'

诀窍是启用echo on并在rem语句后展开％1（也适用于%2 .. %*）。
因此，即使"&"&也可以回应，而不会产生错误。

但是为了能够重定向echo on的输出，你需要两个for循环。

额外字符* #用于保护/?等内容（显示REM的帮助）。
或者，即使在rem之后，行末端的插入符^也可以用作多行字符。

然后从文件中读取 rem参数输出，但要小心 FOR / F应该与延迟扩展一起使用，否则内容为“！”会被摧毁删除param1中的额外字符后，您就可以了。

要以安全的方式使用param1，请启用延迟扩展。

Answer 5

是的，在使用%%1和if以及帮派时，不要忘记使用for等变量。

如果您忘记了双%，那么您将替换（可能为null）命令行参数，您将收到一些非常令人困惑的错误消息。

Answer 6

没有必要使它复杂化。它只是命令％1％2参数，例如，

@echo off

xcopy %1 %2 /D /E /C /Q /H /R /K /Y /Z

echo copied %1 to %2

pause

“暂停”显示批处理文件已完成的操作，并等待您按任意键。将其保存为Windows文件夹中的xx.bat。

要使用它，请键入，例如：

xx c:\f\30\*.* f:\sites\30

这个批处理文件负责处理所有必要的参数，比如只复制文件，更新等等。我在Windows之前使用过它。如果您希望在复制文件时看到这些文件的名称，请忽略Q参数。

Answer 7

@ECHO OFF
:Loop
IF "%1"=="" GOTO Continue
SHIFT
GOTO Loop
:Continue

注意：如果引号中包含"%1"==""，则%1会导致问题。

在这种情况下，请使用IF [%1]==[]或在NT 4（SP6）及更高版本中使用IF "%~1"==""代替。

Answer 8

最近有朋友问过我这个问题，所以我想我会在批处理文件中发布如何处理命令行参数。

这种技术有一些开销，因为你会看到，但它使我的批处理文件非常容易理解和快速实现。以及支持以下结构：

>template.bat [-f] [--flag] [/f] [--namedvalue value] arg1 [arg2][arg3][...]

它的主旨是拥有:init，:parse和:main函数。

使用示例

>template.bat /?
test v1.23
This is a sample batch file template,
providing command-line arguments and flags.

USAGE:
test.bat [flags] "required argument" "optional argument"

/?, --help           shows this help
/v, --version        shows the version
/e, --verbose        shows detailed output
-f, --flag value     specifies a named parameter value

>template.bat          <- throws missing argument error
(same as /?, plus..)
****                                   ****
****    MISSING "REQUIRED ARGUMENT"    ****
****                                   ****

>template.bat -v
1.23

>template.bat --version
test v1.23
This is a sample batch file template,
providing command-line arguments and flags.

>template.bat -e arg1
**** DEBUG IS ON
UnNamedArgument:    "arg1"
UnNamedOptionalArg: not provided
NamedFlag:          not provided

>template.bat --flag "my flag" arg1 arg2
UnNamedArgument:    "arg1"
UnNamedOptionalArg: "arg2"
NamedFlag:          "my flag"

>template.bat --verbose "argument #1" --flag "my flag" second
**** DEBUG IS ON
UnNamedArgument:    "argument #1"
UnNamedOptionalArg: "second"
NamedFlag:          "my flag"

template.bat

@::!/dos/rocks
@echo off
goto :init

:header
    echo %__NAME% v%__VERSION%
    echo This is a sample batch file template,
    echo providing command-line arguments and flags.
    echo.
    goto :eof

:usage
    echo USAGE:
    echo   %__BAT_NAME% [flags] "required argument" "optional argument" 
    echo.
    echo.  /?, --help           shows this help
    echo.  /v, --version        shows the version
    echo.  /e, --verbose        shows detailed output
    echo.  -f, --flag value     specifies a named parameter value
    goto :eof

:version
    if "%~1"=="full" call :header & goto :eof
    echo %__VERSION%
    goto :eof

:missing_argument
    call :header
    call :usage
    echo.
    echo ****                                   ****
    echo ****    MISSING "REQUIRED ARGUMENT"    ****
    echo ****                                   ****
    echo.
    goto :eof

:init
    set "__NAME=%~n0"
    set "__VERSION=1.23"
    set "__YEAR=2017"

    set "__BAT_FILE=%~0"
    set "__BAT_PATH=%~dp0"
    set "__BAT_NAME=%~nx0"

    set "OptHelp="
    set "OptVersion="
    set "OptVerbose="

    set "UnNamedArgument="
    set "UnNamedOptionalArg="
    set "NamedFlag="

:parse
    if "%~1"=="" goto :validate

    if /i "%~1"=="/?"         call :header & call :usage "%~2" & goto :end
    if /i "%~1"=="-?"         call :header & call :usage "%~2" & goto :end
    if /i "%~1"=="--help"     call :header & call :usage "%~2" & goto :end

    if /i "%~1"=="/v"         call :version      & goto :end
    if /i "%~1"=="-v"         call :version      & goto :end
    if /i "%~1"=="--version"  call :version full & goto :end

    if /i "%~1"=="/e"         set "OptVerbose=yes"  & shift & goto :parse
    if /i "%~1"=="-e"         set "OptVerbose=yes"  & shift & goto :parse
    if /i "%~1"=="--verbose"  set "OptVerbose=yes"  & shift & goto :parse

    if /i "%~1"=="--flag"     set "NamedFlag=%~2"   & shift & shift & goto :parse

    if not defined UnNamedArgument     set "UnNamedArgument=%~1"     & shift & goto :parse
    if not defined UnNamedOptionalArg  set "UnNamedOptionalArg=%~1"  & shift & goto :parse

    shift
    goto :parse

:validate
    if not defined UnNamedArgument call :missing_argument & goto :end

:main
    if defined OptVerbose (
        echo **** DEBUG IS ON
    )

    echo UnNamedArgument:    "%UnNamedArgument%"

    if defined UnNamedOptionalArg      echo UnNamedOptionalArg: "%UnNamedOptionalArg%"
    if not defined UnNamedOptionalArg  echo UnNamedOptionalArg: not provided

    if defined NamedFlag               echo NamedFlag:          "%NamedFlag%"
    if not defined NamedFlag           echo NamedFlag:          not provided

:end
    call :cleanup
    exit /B

:cleanup
    REM The cleanup function is only really necessary if you
    REM are _not_ using SETLOCAL.
    set "__NAME="
    set "__VERSION="
    set "__YEAR="

    set "__BAT_FILE="
    set "__BAT_PATH="
    set "__BAT_NAME="

    set "OptHelp="
    set "OptVersion="
    set "OptVerbose="

    set "UnNamedArgument="
    set "UnNamedArgument2="
    set "NamedFlag="

    goto :eof

Answer 9

让我们保持这个简单。

这是.cmd文件。

@echo off
rem this file is named echo_3params.cmd
echo %1
echo %2
echo %3
set v1=%1
set v2=%2
set v3=%3
echo v1 equals %v1%
echo v2 equals %v2%
echo v3 equals %v3%

以下是来自命令行的3次调用。

C:\Users\joeco>echo_3params 1abc 2 def  3 ghi
1abc
2
def
v1 equals 1abc
v2 equals 2
v3 equals def

C:\Users\joeco>echo_3params 1abc "2 def"  "3 ghi"
1abc
"2 def"
"3 ghi"
v1 equals 1abc
v2 equals "2 def"
v3 equals "3 ghi"

C:\Users\joeco>echo_3params 1abc '2 def'  "3 ghi"
1abc
'2
def'
v1 equals 1abc
v2 equals '2
v3 equals def'

C:\Users\joeco>

Answer 10

FOR %%A IN (%*) DO (
    REM Now your batch file handles %%A instead of %1
    REM No need to use SHIFT anymore.
    ECHO %%A
)

循环批处理参数（％*）或者引用它们，然后回显每个参数。

Answer 11

我编写了一个简单的read_params脚本，可以作为函数（或外部.bat）调用，并将所有变量放入当前环境中。它不会修改原始参数，因为该函数正在call带有原始参数的副本。

例如，给出以下命令：

myscript.bat some -random=43 extra -greeting="hello world" fluff

调用函数后，

myscript.bat可以使用变量：

call :read_params %*

echo %random%
echo %greeting%

这里的功能是：

:read_params
if not %1/==/ (
    if not "%__var%"=="" (
        if not "%__var:~0,1%"=="-" (
            endlocal
            goto read_params
        )
        endlocal & set %__var:~1%=%~1
    ) else (
        setlocal & set __var=%~1
    )
    shift
    goto read_params
)
exit /B

<强>限制

无法加载没有值的参数，例如-force。您可以使用-force=true，但我无法想出一种允许空白值的方法，而不会在没有知道参数列表的情况下提前获得价值。

<强>更新日志

的 2016年2月18日

不再需要延迟扩展

现在通过在参数之前查找-来处理其他命令行参数。

Answer 12

要在命令行中引用set变量，您需要使用%a%，例如：

set a=100 
echo %a%  
rem output = 100

注意：这适用于Windows 7专业版。

Answer 13

制作一个新的批处理文件（例如：openclass.bat）并在文件中写下这一行：

java %~n1

然后将批处理文件放入，比如说系统32文件夹，转到Java类文件，右键单击，属性，打开...，然后找到批处理文件，选择它，那就是...... < / p>

它对我有用。

PS：关闭Java类时，我无法找到关闭cmd窗口的方法。现在......

Answer 14

受@Jon的answer elsewhere的启发，我制作了一个更通用的算法来提取命名参数，可选值和开关。

我们假设我们要实现一个实用程序foobar。它需要一个初始命令。它有一个可选参数--foo，它带有一个可选值（当然不能是另一个参数）;如果缺少该值，则默认为default。它还有一个可选参数--bar，它带有必需的值。最后，它可以采用不允许值的标志--baz。哦，这些参数可以按任意顺序排列。

换句话说，它看起来像这样：

foobar <command> [--foo [<fooval>]] [--bar <barval>] [--baz]

这是一个解决方案：

@ECHO OFF
SETLOCAL
REM FooBar parameter demo
REM By Garret Wilson

SET CMD=%~1

IF "%CMD%" == "" (
  GOTO usage
)
SET FOO=
SET DEFAULT_FOO=default
SET BAR=
SET BAZ=

SHIFT
:args
SET PARAM=%~1
SET ARG=%~2
IF "%PARAM%" == "--foo" (
  SHIFT
  IF NOT "%ARG%" == "" (
    IF NOT "%ARG:~0,2%" == "--" (
      SET FOO=%ARG%
      SHIFT
    ) ELSE (
      SET FOO=%DEFAULT_FOO%
    )
  ) ELSE (
    SET FOO=%DEFAULT_FOO%
  )
) ELSE IF "%PARAM%" == "--bar" (
  SHIFT
  IF NOT "%ARG%" == "" (
    SET BAR=%ARG%
    SHIFT
  ) ELSE (
    ECHO Missing bar value. 1>&2
    ECHO:
    GOTO usage
  )
) ELSE IF "%PARAM%" == "--baz" (
  SHIFT
  SET BAZ=true
) ELSE IF "%PARAM%" == "" (
  GOTO endargs
) ELSE (
  ECHO Unrecognized option %1. 1>&2
  ECHO:
  GOTO usage
)
GOTO args
:endargs

ECHO Command: %CMD%
IF NOT "%FOO%" == "" (
  ECHO Foo: %FOO%
)
IF NOT "%BAR%" == "" (
  ECHO Bar: %BAR%
)
IF "%BAZ%" == "true" (
  ECHO Baz
)

REM TODO do something with FOO, BAR, and/or BAZ
GOTO :eof

:usage
ECHO FooBar
ECHO Usage: foobar ^<command^> [--foo [^<fooval^>]] [--bar ^<barval^>] [--baz]
EXIT /B 1

使用SETLOCAL以便变量不会转义到调用环境中。
如果有人在调用环境中定义变量，请不要忘记初始化变量SET FOO=等。
使用%~1删除引号。
使用IF "%ARG%" == ""而非IF [%ARG%] == []，因为[和]根本不会播放以空格结尾的值。
即使您SHIFT块内IF，%~1之类的当前参数也不会更新，因为它们是在解析IF时确定的。您可以在%~1块中使用%~2和IF，但这会让您感到困惑，因为您有一个SHIFT。为了清楚起见，您可以将SHIFT放在块的末尾，但这可能会丢失和/或混淆人们。因此，在块外“捕获”%~1和%~1似乎是最好的。
您不想使用参数代替其他参数的可选值，因此您必须检查IF NOT "%ARG:~0,2%" == "--"。
当使用其中一个参数时，请注意SHIFT。
重复的代码SET FOO=%DEFAULT_FOO%令人遗憾，但另一种方法是在IF "%FOO%" == "" SET FOO=%DEFAULT_FOO%块之外添加IF NOT "%ARG%" == ""。但是因为它仍在IF "%PARAM%" == "--foo"块中，所以%FOO%值在您进入块之前已经过评估和设置，因此您永远不会检测到两者 { {1}}参数存在且 --foo值缺失。
请注意%FOO%将错误消息发送给stderr。
想在Windows批处理文件中留空吗？您必须使用ECHO Missing bar value. 1>&2或其中一种变体。

Answer 15

简单的解决方案（即使问题很旧）

Test1.bat

echo off
echo "Batch started"
set arg1=%1
echo "arg1 is %arg1%"
echo on
pause

CallTest1.bat

call "C:\Temp\Test1.bat" pass123

输出

YourLocalPath>call "C:\Temp\test.bat" pass123

YourLocalPath>echo off
"Batch started"
"arg1 is pass123"

YourLocalPath>pause
Press any key to continue . . .

其中YourLocalPath是当前目录路径。

为简单起见，将命令参数存储在变量中，并使用变量进行比较。

它不仅易于编写，而且易于维护，因此，如果以后有人或您长时间阅读脚本后，将易于理解和维护。

要内联编写代码：请参见其他答案。

Answer 16

批处理文件

set argument1=%1
set argument2=%2
echo %argument1%
echo %argument2%

％1和％2分别返回第一个和第二个参数值。

在命令行中，传递thestrmt

Directory> batchFileName admin P@55w0rd

输出将为

admin
P@55w0rd

Answer 17

每个人的回答都非常复杂，但实际上非常简单。 %1 %2 %3 等是解析到文件的参数。 %1 是论证 1，%2 是论证 2，依此类推。

所以，如果我有一个包含这个的 bat 脚本：

@echo off
echo %1

当我运行批处理脚本时，我输入：

C:> script.bat Hello

脚本将简单地输出：

Hello

这对于脚本中的某些变量非常有用，例如姓名和年龄。所以，如果我有这样的脚本：

@echo off
echo Your name is: %1
echo Your age is: %2

当我输入时：

C:> script.bat Oliver 1000

我得到这个输出：

Your name is: Oliver
Your age is: 1000

Answer 18

要使用循环，请以纯批处理的形式获取所有参数：

@echo off && setlocal EnableDelayedExpansion

 set "_cnt=0" && for %%Z in (%*) do ( 
 set "_arg_=%%Z" && set /a "_cnt=!_cnt! + 1" && set "_arg_[!_cnt!]=!_arg_!"
 shift && for /l %%l in (!_cnt! 1 !_cnt!) do echo/ The argument n:%%l is: !_arg_[%%l]!
 )

goto :eof

您的代码已准备就绪，可以在需要的地方使用其参数编号，例如...

 @echo off && setlocal EnableDelayedExpansion

 set "_cnt=0" && for %%Z in (%*) do ( 
 set "_arg_=%%Z" && set /a "_cnt=!_cnt! + 1" && set "_arg_[!_cnt!]=!_arg_!"
 shift 

 )

 fake-command /u !_arg_[1]! /p !_arg_[2]! > test-log.txt

Answer 19

配对参数

如果您更喜欢在键值对中传递参数，则可以使用以下命令：

@echo off

setlocal enableDelayedExpansion

:::::  asigning arguments as a key-value pairs:::::::::::::
set counter=0
for %%# in (%*) do (    
    set /a counter=counter+1
    set /a even=counter%%2
    
    if !even! == 0 (
        echo setting !prev! to %%#
        set "!prev!=%%~#"
    )
    set "prev=%%~#"
)
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

:: showing the assignments
echo %one% %two% %three% %four% %five%

endlocal

还有一个示例：

c:>argumentsDemo.bat one 1 "two" 2 three 3 four 4 "five" 5
1 2 3 4 5

预定义变量

您还可以预先设置一些环境变量。可以通过在控制台或setting them from my computer中设置它们来完成：

@echo off

if defined variable1 (
    echo %variable1%
)

if defined variable2 (
    echo %variable2%
)

并这样称呼它：

c:\>set variable1=1

c:\>set variable2=2

c:\>argumentsTest.bat
1
2

具有列出值的文件

您还可以指向已预设所需值的文件。如果这是脚本：

@echo off

setlocal
::::::::::
set "VALUES_FILE=E:\scripts\values.txt"
:::::::::::


for /f "usebackq eol=: tokens=* delims=" %%# in ("%VALUES_FILE%") do set "%%#"

echo %key1% %key2% %some_other_key%

endlocal

和值文件是这个：

:::: use EOL=: in the FOR loop to use it as a comment

key1=value1

key2=value2

:::: do not left spaces arround the =
:::: or at the begining of the line

some_other_key=something else

and_one_more=more

调用它的输出将是：

value1 value2其他

当然，您可以组合所有方法。还要检查arguments syntax，shift

如何将参数传递给批处理文件？

19 个答案:

配对参数

预定义变量

具有列出值的文件