Question

我一直在尝试从XML中获取值并创建此输出：

OUTPUT1=Question1=No&Question2=Yes

我目前的输出是：

    Question1=No
    Question2=Yes

我不知道这样做的最佳方法，我是XSLT的新手，我正在考虑将这些值存储到变量中，并在以后使用它们： OUTPUT1 =变量1＆安培;变量2

但即便对我来说这是一个挑战，有人可以帮我指点吗？

XSLT

<xsl:template match="/">
    <xsl:call-template name="processQuestion">
        <xsl:with-param name="name" select="'ADM_1'"></xsl:with-param>
    </xsl:call-template>
    <xsl:call-template name="processQuestion">
        <xsl:with-param name="name" select="'ADM_2'"></xsl:with-param>
    </xsl:call-template>
</xsl:template>

<xsl:template name="processQuestion">
    <xsl:param name="name"></xsl:param>
    <xsl:apply-templates select="//x:form/x:add[@name=$name]" mode="process" />
</xsl:template>

<xsl:template match="x:add" mode="process">
    <xsl:value-of select="@title"/>=<xsl:value-of select="."/>
    <xsl:text>&#xa;</xsl:text>
</xsl:template>

XML

<?xml version="1.0" encoding="iso-8859-1"?>
<transaction xmlns="TransactionDataOfRequest" xmlns:xsd="http://www.w3.org/2001/XMLSchema"     xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">
  <success>true</success>
  <code>0</code>
  <value>
    <form>
      <add name="ADM_1" title="Question 1" type="String" isList="false">No</add>
      <add name="ADM_2" title="Question 2" type="String" isList="false">Yes</add>
    </form>
  </value>
</transaction>

可变

    <xsl:variable name="test">
      <xsl:value-of select="."/>
    </xsl:variable>

我也试过这个：

<?xml version="1.0"?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:x="TransactionDataOfRequest">
  <xsl:output method="text" indent="no"/>
  <xsl:output omit-xml-declaration="yes" encoding="UTF-8"/>
  <xsl:strip-space elements="*"/>

  <xsl:template match="/">
    <xsl:param name="param1" select="'ADM_1'"/>
    <xsl:param name="param2" select="'ADM_2'"/>

    <xsl:for-each select="//x:form/x:add">
      <xsl:if test="@name=$param1">
Question1=<xsl:value-of select="."/>
      </xsl:if>
    </xsl:for-each>

    <xsl:for-each select="//x:form/x:add">
      <xsl:if test="@name=$param2">
        <xsl:variable name="test">
          <xsl:value-of select="."/>
        </xsl:variable>
Question2=<xsl:copy-of select="$test" />
      </xsl:if>
    </xsl:for-each>
  </xsl:template>
</xsl:stylesheet>

这是我的第一次尝试，实际上我能够将值保存到变量中，但该变量只存在于该模板中吗？

Answer 1

如何以简单的方式做到这一点？

<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:tx="TransactionDataOfRequest">

<xsl:output method="text" encoding="utf-8"/>

<xsl:template match="/">
    <xsl:text>OUTPUT1=</xsl:text>
    <xsl:for-each select="tx:transaction/tx:value/tx:form/tx:add[@name='ADM_1' or @name='ADM_2']">
        <xsl:value-of select="@title"/>
        <xsl:text>=</xsl:text>
        <xsl:value-of select="."/>
        <xsl:if test="position()!=last()">
            <xsl:text>&amp;</xsl:text>
        </xsl:if>
    </xsl:for-each>

</xsl:template>

</xsl:stylesheet>

应用于以下示例输入：

<?xml version="1.0" encoding="iso-8859-1"?>
<transaction xmlns="TransactionDataOfRequest" xmlns:xsd="http://www.w3.org/2001/XMLSchema"     xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">
    <success>true</success>
    <code>0</code>
    <value>
    <form>
        <add name="ADM_1" title="Question 1" type="String" isList="false">No</add>
        <add name="XCL_3" title="Question 3" type="String" isList="false">Yes</add>
        <add name="ADM_2" title="Question 2" type="String" isList="false">Yes</add>
    </form>
    </value>
</transaction>

生成结果::

OUTPUT1=Question 1=No&Question 2=Yes

我不确定您是否需要删除原始名称中的空格。

Answer 2

为什么要将值存储在变量中？是否需要它？

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:x="TransactionDataOfRequest">
<xsl:output method="text" indent='yes'/>
<xsl:strip-space elements="*"/>
<xsl:template match="/">
    <xsl:variable name="temp">
        <xsl:value-of select="for $var in //x:form/x:add return concat(translate($var/@title,' ',''),$var)" separator="&amp;"/>
    </xsl:variable>
    <xsl:value-of select="concat('OUTPUT1=',$temp)"/>
</xsl:template>
</xsl:stylesheet>

使用XSLT从XML获取特定值

2 个答案: