Question

这个问题是我在此问到的另一个问题answered。

我有以下功能：

MotiColor startColor;
MotiColor endColor;

void setup()
{
    // Begin strip.
    strip.begin();

    // Initialize all pixels to 'off'.
    strip.show();

    Serial1.begin(9600);

    startColor = MotiColor(0, 0, 0);
    endColor = MotiColor(0, 0, 0);
}

void loop () {
}

int tinkerSetColour(String command)
{
    strip.show();

    int commaIndex = command.indexOf(',');
    int secondCommaIndex = command.indexOf(',', commaIndex+1);
    int lastCommaIndex = command.lastIndexOf(',');

    String red = command.substring(0, commaIndex);
    String grn = command.substring(commaIndex+1, secondCommaIndex);
    String blu = command.substring(lastCommaIndex+1);

    startColor = MotiColor(red.toInt(), grn.toInt(), blu.toInt());

    int16_t redDiff = endColor.getR() - startColor.getR();
    int16_t greenDiff = endColor.getG() - startColor.getG();
    int16_t blueDiff = endColor.getB() - startColor.getB();

    int16_t _delay = 500;
    int16_t duration = 3500;
    int16_t steps = duration / _delay;

    int16_t redValue, greenValue, blueValue;

    for (int16_t i = steps; i >= 0; i--) {
        redValue = (int16_t)startColor.getR() + (redDiff * i / steps);
        greenValue = (int16_t)startColor.getG() + (greenDiff * i / steps);
        blueValue = (int16_t)startColor.getB() + (blueDiff * i / steps);

        sprintf(rgbString, "%i,%i,%i", redValue, greenValue, blueValue);
        Spark.publish("rgb", rgbString);

        for (uint16_t i = 0; i < strip.numPixels(); i++) {
            strip.setPixelColor(i, strip.Color(redValue, greenValue, blueValue));
        }

        delay(_delay);
    }

    delay(_delay);

    for (uint16_t i = 0; i < strip.numPixels(); i++) {
        strip.setPixelColor(i, strip.Color(endColor.getR(), endColor.getG(), endColor.getB()));
    }

    delay(_delay);

    endColor = MotiColor(startColor.getR(), startColor.getG(), startColor.getB());

    return 1;
}

我正确看到发布的结果：

这是从OFF（0,0,0） - ＆gt; RED（255,0,0） - ＆gt;格林（0,255,0）。

enter image description here

当我通过Spark.publish()事件将结果发布回Web控制台时，它工作正常，但是实际的Neopixel LED不会像预期的那样从颜色渐变到颜色。它们只是从颜色变为颜色而不是在它们之间很好地褪色。

我只是想知道我哪里出错了，或者我如何改进我的代码，以便实际看到实时消失。

Answer 1

您必须在for循环中调用strip.show（），如下所示：

for (int16_t i = steps; i >= 0; i--) {
    redValue = (int16_t)startColor.getR() + (redDiff * i / steps);
    greenValue = (int16_t)startColor.getG() + (greenDiff * i / steps);
    blueValue = (int16_t)startColor.getB() + (blueDiff * i / steps);

    sprintf(rgbString, "%i,%i,%i", redValue, greenValue, blueValue);
    Spark.publish("rgb", rgbString);

    for (uint16_t i = 0; i < strip.numPixels(); i++) {
        strip.setPixelColor(i, strip.Color(redValue, greenValue, blueValue));
    }



    // !!! Without this, you'll only see the result the next time you call
    // tinkerSetColor() !!!
    strip.show();



    delay(_delay);
}

要了解正在发生的事情，您可以查看NeoPixel库源代码。您将看到strip.setPixelColor()仅将RGB值存储在内存中（将其视为绘图缓冲区，以便您可以立即更新整个条带，这在您了解控制器芯片的工作原理时有意义）。调用strip.show()会导致将值推送到串行中的每个像素的例程运行。

Neopixel arduino使用Sparkcore从颜色渐变到颜色

1 个答案: